net-analyzer/notus-scanner: add 22.6.3

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/37026
Signed-off-by: Florian Schmaus <flow@gentoo.org>

net-analyzer/notus-scanner/Manifest

@@ -1 +1,2 @@
 DIST notus-scanner-22.6.2.tar.gz 316406 BLAKE2B c24ec5e4fd9f8fc181145d64580d04f7045ccf1a7570f855f0a8a79bcea842fe7a73d91fadecd61c10b94cb3ee68ecae98b0f91b4059b84258765be98c95057f SHA512 ecbbb79950908641c2b83d379d141b189b8e0e27cac17753cbb381a5f4ebf28d7100f60bd24fc284c2681abc889f6fee36a64f469ac0b37323940eaeae7e7522
+DIST notus-scanner-22.6.3.tar.gz 293997 BLAKE2B 889416d2324088dc11f2df5146b3c88b276d1170552f55b2cb7ef49f4d8d855b98d6c0e53a1d49bd725b97b88c12df69a1997a38a614aa941dd699d0efb1de51 SHA512 fc3a05a3a9d61dd0b7a9913cfbbf507fec9dd3797a42a82283d14ab7fa8090fbc847487cf3a1d064f49572dda9acadba4bd7d30003fd32a179f572e327254546

net-analyzer/notus-scanner/notus-scanner-22.6.3.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+DISTUTILS_USE_PEP517=poetry
+inherit distutils-r1 readme.gentoo-r1 systemd
+
+DESCRIPTION="Notus is a vulnerability scanner for creating results from local security checks"
+HOMEPAGE="https://github.com/greenbone/notus-scanner"
+SRC_URI="https://github.com/greenbone/notus-scanner/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="AGPL-3 AGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	acct-user/gvm
+	net-libs/paho-mqtt-c
+	>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+	>=dev-python/python-gnupg-0.5.1[${PYTHON_USEDEP}]
+	<dev-python/packaging-24.1[${PYTHON_USEDEP}]
+	>=dev-python/paho-mqtt-1.5.1[${PYTHON_USEDEP}]
+	<dev-python/tomli-3[${PYTHON_USEDEP}]
+"
+
+RDEPEND="
+	${DEPEND}
+	app-misc/mosquitto
+"
+
+PATCHES=(
+	"${FILESDIR}"/notus-scanner-22.6.2-remove-tests.patch
+)
+
+DOC_CONTENTS="
+For validating the feed content, a GnuPG keychain with the Greenbone Community Feed integrity key needs to be created.
+Please, read here on how to create it:
+https://greenbone.github.io/docs/latest/22.4/source-build/index.html#feed-validation
+https://wiki.gentoo.org/wiki/Greenbone_Vulnerability_Management#Notus_Scanner
+
+To enable feed validation, edit /etc/gvm/${PN}.toml
+and set
+disable-hashsum-verification = false"
+DISABLE_AUTOFORMATTING=true
+
+distutils_enable_tests unittest
+
+python_compile() {
+	distutils-r1_python_compile
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	insinto /etc/gvm
+	use prefix || fowners -R gvm:gvm /etc/gvm
+	newins "${FILESDIR}/${PN}.toml" "${PN}.toml"
+	use prefix || fowners gvm:gvm "/etc/gvm/${PN}.toml"
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/notus
+	keepdir /var/lib/notus/products
+	keepdir /var/lib/notus/advisories
+	if ! use prefix; then
+		fowners -R gvm:gvm /var/lib/notus
+	fi
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+
+	systemd_dounit config/${PN}.service
+
+	systemd_install_serviced "${FILESDIR}/notus-scanner.service.conf" \
+			${PN}.service
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}