dev-python/csvkit: Bump to 1.0.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/csvkit/Manifest

@@ -1 +1,2 @@
 DIST csvkit-1.0.5.tar.gz 3783495 BLAKE2B 19210c23480cb3068af74c922a3495612f40bbf5c4985f7018c9c185564dd0c101292f165ddd03440220f582bfdc1590e2f75e8e5c92edd71e76e46a73b26547 SHA512 62dc7a5eefeda9c8824b24f8844b6c1ead5449797d9d004111885b03a1989ad89d1f48b3b7d4a69130885b85cc3c1352910737e416fc19f2038525632b1569f6
+DIST csvkit-1.0.6.tar.gz 3784737 BLAKE2B b1e4583443cbfc62f713d3b311bbe313cf4e69b7aa5aa13dc6970375a727a804ba1dbd176b25487027d3bc1a5696f2ce649a460c91ef7c5591c33bb3c6f48c33 SHA512 fb37404405f2f2c0bf803a1df8186aa9e3b11cbf3c4f6e1fe6dc06d53730aa91d462bebcca3917e9a451f1d81df053abd9ceedfaab085ab696f9ba701c873323

dev-python/csvkit/csvkit-1.0.6.ebuild

@@ -0,0 +1,48 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="A suite of utilities for converting to and working with CSV."
+HOMEPAGE="https://github.com/wireservice/csvkit https://pypi.org/project/csvkit/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +xml"
+RESTRICT="!test? ( test )"
+
+# Other packages have BDEPEND="test? ( dev-python/csvkit[xml] )"
+AGATE_VERSION_DEP=">=dev-python/agate-1.6.1"
+TEST_AGAINST_RDEPEND="xml? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+RDEPEND="
+	${AGATE_VERSION_DEP}[${PYTHON_USEDEP}]
+	>=dev-python/agate-excel-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/agate-dbf-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/agate-sql-0.5.3[${PYTHON_USEDEP}]
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+
+	${TEST_AGAINST_RDEPEND}
+"
+BDEPEND="test? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local pytest_args test_name xfails
+
+	xfails=(
+		tests/test_utilities/test_in2csv.py::TestIn2CSV::test_convert_dbf
+	)
+
+	for test_name in "${xfails[@]}"; do
+		pytest_args+=(--deselect "${test_name}")
+	done
+
+	epytest "${pytest_args[@]}"
+}