dev-python/fonttools: Bump to 4.39.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/fonttools/Manifest

@@ -1 +1,2 @@
 DIST fonttools-4.38.0.gh.tar.gz 3603281 BLAKE2B 8ec558c35cc10b32760eb199dce7c40934210db9ba8c9b0ad7a8cd2ca206260d2d73769bd1ff4cb597dd46cd50a42d733c967199120366e22abc5ee2b81e0919 SHA512 438694e7a4c19ee63ab504763793c0219d96fdc58095fe55a4f44726e96a3ec8ae63066aa47a341a059c7a2c9893b9bbbdfc8ab4d75c177cbd90986debc31431
+DIST fonttools-4.39.0.gh.tar.gz 3673934 BLAKE2B 468f8798b06593f69b4130f06d52134b9c86a414ba534a352e15bb16d787e11a6b692d406e545aa137d5d132aa33684f44e98a520ce13fe6c8e4dcf81fc64e69 SHA512 f9613651082ae8fb0dd3fba66549f90001d8cb3c71785f9e5b692513984d26d63d027dfb67e1dbe1a22c6e8c393e6ed21af1bfcd5b2f766c8534577cbd211616

dev-python/fonttools/fonttools-4.39.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	export FONTTOOLS_WITH_CYTHON=1
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
+}