dev-python/setuptools: Bump to 59.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/setuptools/Manifest

@@ -3,3 +3,4 @@ DIST python-gentoo-patches-3.10.0rc1.tar.xz 8112 BLAKE2B d6f9b44c5a231f447ffe353
 DIST setuptools-57.5.0.tar.gz 2141727 BLAKE2B 54c065e0bdcb0c3a0a76026d78ab26615e07ee013e684ef18c3731757a38efe38d21d4c99b687595873679d77ab8381cccc483847467c98eb7086d9cac5bd8ec SHA512 9dae7cbddcca0859d128f528232c2ab6baca2b4447bba129a7bbc014c98a8ecc866cc71c7e93900bb93ea4bbbe5e398c1c3b4a4867afb2caf2c38a2d5a46d67c
 DIST setuptools-59.2.0.tar.gz 2281261 BLAKE2B 40d929a7a15d469e66b5f0db744663d0debfc9559806bebd141f5659965e47ebbd3f05ae4fe0dfd514db10507c5fffb4ab427eb55b61c2febb0dc6b47d02ca6b SHA512 cd6acf817c548ef518f0e64172f8263b181eddeaf0cbe527b30a5db9ecf0f985b76a6d9c28a54ae7a743debb844c0c75781ebcdf81eb478f2bd67b81d1e3f847
 DIST setuptools-59.4.0.tar.gz 2281497 BLAKE2B 8267d6d4c373f44659b22155848fe064c7575cb74702ad77894adddcf05d805324bcd68505270bd05e81ec5702cb1dd47beec62de26f17a6459683df8cd1414b SHA512 bc7b1eb89c40ffe64b827bfbe4981dc157a7cdbd5924e53483ff69ad7e9613f6957bc36366d45c45e1e49f2d504a7b2d81677690722d4d1f1ab2e62be05b617f
+DIST setuptools-59.5.0.tar.gz 2281671 BLAKE2B 51b3435a1d7962a06f7cf07c31487a1404274a54a1fae0567c3953686cbf3b3160327a56c599e80ce70fe8f56dc817fc76d0e4371d3622b5c6235b0fdc555980 SHA512 2ad0aa7c05d9664d0bdc17d93ba518903f14f0e8fe568bcc4615f8a651e3e35843d2747200e20a796f250f1bcebfa057c94b7942875aa1badd770ca12e847c32

dev-python/setuptools/setuptools-59.5.0.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	distutils_install_for_testing
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_distutils_adoption.py
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}