net-libs/xdp-tools: restore 1.2.8

Needed because bpftool isn't keyworded everywhere. Rescued from
8eea55ff63.

Bug: https://bugs.gentoo.org/899684
Signed-off-by: Sam James <sam@gentoo.org>

net-libs/xdp-tools/Manifest

@@ -1 +1,2 @@
+DIST xdp-tools-1.2.8.tar.gz 253786 BLAKE2B f745085b73da5193c3cdaf60c20dfa5de62f3d83487413c87b4c3d07b755dcf91cfbeb4ba970b4e04eef74b4cec4238057f4462074f49b7139d7652cb0f22998 SHA512 6ada9e433fcbefd13cebdffe93c3ce9159e9e09f1498d1615918ca6ecc4f11f03fcd9096980e8ceb7de126d4d8b953fa64917e777d54b5a3dfd1a9556de81626
 DIST xdp-tools-1.3.1.tar.gz 330516 BLAKE2B 89a61f47ba26efe6d0630d971e913e034d111d05c896e5af1bb28e6cb4e94133e6ecd827a10ee12a935ae2e6856f04556ac564ded1bcc65182766d656f8d0c5f SHA512 9dd434095a043158d14fb6829fa632fc4a0714dc0b6e08c219dfb55cb9f34005300db750115e08bd54210e90142bd499904616da077b8aa827e4de28c31be637

net-libs/xdp-tools/xdp-tools-1.2.8.ebuild

@@ -0,0 +1,52 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="The libxdp library and various tools for use with XDP"
+HOMEPAGE="https://github.com/xdp-project/xdp-tools"
+SRC_URI="https://github.com/xdp-project/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1 BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+IUSE="+tools"
+
+DEPEND="dev-libs/libbpf:=
+	sys-libs/zlib
+	net-libs/libpcap
+	virtual/libelf"
+RDEPEND="${DEPEND}"
+BDEPEND=">=sys-devel/clang-10.0.0"
+
+# Not prebuilt -- we build them -- but they're not ordinary ELF objects either.
+QA_PREBUILT="usr/lib/bpf/*.o"
+
+MAKEOPTS+=" V=1"
+
+src_configure() {
+	export PRODUCTION=1
+	export DYNAMIC_LIBXDP=1
+	export FORCE_SYSTEM_LIBBPF=1
+	default
+}
+
+src_install() {
+	export PREFIX="${EPREFIX}/usr"
+	export LIBDIR="${PREFIX}/$(get_libdir)"
+	export BPF_OBJECT_DIR="${PREFIX}/lib/bpf"
+	default
+
+	# To remove the scripts/testing files that are installed.
+	rm -r "${ED}/usr/share/xdp-tools" || die
+	# We can't control static archive generation yet.
+	rm "${ED}/usr/$(get_libdir)/libxdp.a" || die
+
+	use tools || { rm "${ED}/usr/sbin"/* || die; }
+
+	# These are ELF objects but BPF ones.
+	dostrip -x /usr/lib/bpf
+}
+
+src_test() { :; }