app-text/libspelling: add 0.4.6

Also fix dependencies.

Closes: https://bugs.gentoo.org/949668
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

app-text/libspelling/Manifest

@@ -1 +1,2 @@
 DIST libspelling-0.4.5.tar.bz2 71413 BLAKE2B 5e6c00d9cd521f560082d76da75fd070a59f3b8dec269db95ffa88f9c216557587e180fcbc7399ea0dbcfe605de024344a4b17af60d4d31b1686f64b5df6fca9 SHA512 ab8fd439855d84c4e681fba0b5030bdcf34d0f4940a3b818aab4d297975acf37e437b141d678a482ebda240d23ecd7875e6c8656be6e1bb3c9c129f2169a8ced
+DIST libspelling-0.4.6.tar.bz2 71184 BLAKE2B ff5a30b7ba43faaf9bd42ed7d85624cf7bf1f5e3c4c242c4c4dbcd79ec92fafc2d0ddc49218d98b7d06b5a7b7aacf6527a0e481c78f8a61bea8b5fa976588de3 SHA512 f5aeda95a116cab8cb84a5ec9567fb9c9fb637b73773a7d0614e39e73de087a13e2cc5b6e1e853c3f2f3dacb38a04f7c44f8f89fe179dfe7689baef704331b65

app-text/libspelling/libspelling-0.4.6.ebuild

@@ -0,0 +1,60 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson vala
+
+DESCRIPTION="A GNOME library for spellchecking"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libspelling"
+SRC_URI="https://gitlab.gnome.org/GNOME/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~amd64 ~loong ~riscv ~x86"
+IUSE="gtk-doc sysprof vala"
+
+RDEPEND="
+	dev-libs/glib:2
+	>=gui-libs/gtk-4.15.5:4
+	>=gui-libs/gtksourceview-5.10.0:5
+	app-text/enchant:2
+	dev-libs/icu:=
+"
+DEPEND="${RDEPEND}
+	sysprof? ( dev-util/sysprof-capture:4 )
+	vala? (
+		$(vala_depend)
+		>=gui-libs/gtksourceview-5.6:5[vala]
+	)
+"
+BDEPEND="
+	dev-libs/gobject-introspection
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gi-docgen )
+"
+
+src_prepare() {
+	use vala && vala_setup
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denchant=enabled
+		-Dinstall-static=false
+		$(meson_use gtk-doc docs)
+		$(meson_use sysprof)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}