dev-python/poetry: Bump to 2.4.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/poetry/Manifest

@@ -1,2 +1,4 @@
 DIST poetry-2.4.1.tar.gz 3282327 BLAKE2B 6b4a12d419ef0845acc862b4b4b0f7afe515cc97e303d39d0b936d200bec26ab71f0898107af89160b98ce8aaeebb30b5548c5c86f4e163f1a730bead74fc472 SHA512 71f0a959058fe8c1d2495f486c8f7771de0ec7166fc1ed1d6b7a2813e448b5ffb1c7429c5d5d1930fce33caf3f0f2f5c5a0b9fd199a53c7aa1d2ca6e9d25645b
 DIST poetry-2.4.1.tar.gz.provenance 9481 BLAKE2B a90a89ba0260090b09e831b6f21a7c42b590fd43e56f81a3d75a63b64ba527dbdae2c8b7fde2eaf233dc67b9505935db8785905fcfb9426f4a15b1b74eda9b8e SHA512 f33ea62e05153d3f4d884bfb746c062411b1b999ae3bea512c79fece60b5f8e7360e4746b321454d4d8a8bc92714a628c5ae08693d2837d17bc6f3dce71f9515
+DIST poetry-2.4.2.tar.gz 3285341 BLAKE2B f84efd3324be23882146b1ffc533518dc670c9b1c5a3b993cdc7a64b132f700391ebb194033c38590621c62f7cafb3a49e4ab76590feb2eb26d1bd610436bf83 SHA512 8a3a013662cc32a02adace643344dd88dbd1f48316ee6e32d630d28af46c422654a8795a7c96e0f2cdf06d885c1d32bb59a6b453f4e20a032fd6a9876902d4b2
+DIST poetry-2.4.2.tar.gz.provenance 9754 BLAKE2B f964b0d78a7264c444a54f0bd713793b7d627fe24b94bfb8f84924daced1a9e17a96feca9b421bc70d0dc2ed4712547e612c71d30704cfe5725ecf332fbcda56 SHA512 9115dcff2f98710e20ea18d971a3f0efde1c11a86fc7ad79c33b730533570a6be98994d0b8439e7b8d4db5e840460c8aafd15603b9c382c538d7d3588d2f56a9

dev-python/poetry/poetry-2.4.2.ebuild

@@ -0,0 +1,80 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry-core
+PYPI_VERIFY_REPO=https://github.com/python-poetry/poetry
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A frontend for poetry - a python dependency management and packaging tool"
+HOMEPAGE="
+	https://python-poetry.org/
+	https://github.com/python-poetry/poetry/
+	https://pypi.org/project/poetry/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	=dev-python/poetry-core-$(ver_cut 1-2)*[${PYTHON_USEDEP}]
+	>=dev-python/build-1.2.1[${PYTHON_USEDEP}]
+	>=dev-python/cachecontrol-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cleo-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/dulwich-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/fastjsonschema-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.6.2[${PYTHON_USEDEP}]
+	>=dev-python/installer-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-25.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.2[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.06.10[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.12[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/shellingham-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11.6[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2022.5.19[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.26.6[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/deepdiff-6.3.1[${PYTHON_USEDEP}]
+		>=dev-python/jaraco-classes-3.3.1[${PYTHON_USEDEP}]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,xdist} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internal test for lockfile being up-to-date
+	# Meaningless, also sdist does not include lockfile
+	tests/installation/test_installer.py::test_not_fresh_lock
+
+	# broken if poetry-plugin-export is installed
+	'tests/console/test_application_command_not_found.py::test_application_command_not_found_messages[x-None]'
+
+	# unhappy with system Python liking 'linux' tag more?
+	tests/installation/test_chef.py::test_prepare_directory_with_extensions
+)
+
+src_prepare() {
+	# unpin
+	sed -e 's:,<[0-9.]*::' -e 's:==\([0-9]\):>=\1:' -i pyproject.toml || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -m "not network"
+}