mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
kde-apps/cantor: 20.04.3 version bump
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
@@ -1,2 +1,3 @@
|
||||
DIST cantor-19.12.3.tar.xz 9014164 BLAKE2B d88c820a36806facc76197ba2e29fece503fba2e3bafe5d856c64243b6d098babc4ae6da082e7c07f20b499f9ed2373aeccfbb5dcede196214d8a2c582de302a SHA512 83324f7a1702b5ed5d74ecab7664b653b8f318b03b6c856c7a70133b2aaf0927cf8b16a8ba9e27a7224d4d8d5900f1dcdbc89e70f40871f000db29f6f072668a
|
||||
DIST cantor-20.04.2.tar.xz 9028088 BLAKE2B ff2b8ed723f0c1bf05b93b12af75b358663e5ad6fb3d9ea1d5209637ff581216b0687fe0bd9d4bab42399d07035f0f9e99cd2f2ca8909a8488ac1ee55ff5e0cb SHA512 f2f65a1cecfbb2edc2ade5fcecc80f9ccfba92a61960ba2e7038f30ef7260220eb2b6c20cefe74a9cedf96160baaf0a4b8b6b99693db45031210733d492c4196
|
||||
DIST cantor-20.04.3.tar.xz 9029068 BLAKE2B c5b436304d3aa84150a0994d556318600f73ccb606b59fc67d8476828c356f54d64cda85f781c9c939403b0bb6808e2a943d37ad306fbc751800944ad27e74f4 SHA512 07351d8b4b72653394a337bc3ae5c8f8c669dd8cd66f4cf9d41bbdd25b47a8b3666f79580e319ef56c878ab626ce959d825b4a34243c5f639de96674a1bc111d
|
||||
|
||||
@@ -0,0 +1,109 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
CMAKE_MAKEFILE_GENERATOR="emake"
|
||||
ECM_HANDBOOK="forceoptional"
|
||||
ECM_TEST="forceoptional"
|
||||
PYTHON_COMPAT=( python3_{7,8} )
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
KFMIN=5.70.0
|
||||
QTMIN=5.14.2
|
||||
inherit ecm kde.org python-single-r1
|
||||
|
||||
DESCRIPTION="Interface for doing mathematics and scientific computing"
|
||||
HOMEPAGE="https://kde.org/applications/education/org.kde.cantor
|
||||
https://edu.kde.org/cantor/"
|
||||
|
||||
LICENSE="GPL-2" # TODO: CHECK
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+analitza julia lua postscript python qalculate R"
|
||||
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
# TODO Add Sage Mathematics Software backend (http://www.sagemath.org)
|
||||
DEPEND="
|
||||
>=dev-qt/qtgui-${QTMIN}:5
|
||||
>=dev-qt/qtprintsupport-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=dev-qt/qtxml-${QTMIN}:5
|
||||
>=dev-qt/qtxmlpatterns-${QTMIN}:5
|
||||
>=kde-frameworks/karchive-${KFMIN}:5
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:5
|
||||
>=kde-frameworks/kconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kcrash-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:5
|
||||
>=kde-frameworks/kio-${KFMIN}:5
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:5
|
||||
>=kde-frameworks/kparts-${KFMIN}:5
|
||||
>=kde-frameworks/kpty-${KFMIN}:5
|
||||
>=kde-frameworks/ktexteditor-${KFMIN}:5
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:5
|
||||
>=kde-frameworks/syntax-highlighting-${KFMIN}:5
|
||||
analitza? ( >=kde-apps/analitza-${PVCUT}:5 )
|
||||
julia? ( dev-lang/julia )
|
||||
lua? ( dev-lang/luajit:2 )
|
||||
qalculate? (
|
||||
sci-libs/cln
|
||||
sci-libs/libqalculate:=
|
||||
)
|
||||
postscript? ( app-text/libspectre )
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
)
|
||||
R? ( dev-lang/R )
|
||||
"
|
||||
RDEPEND="${DEPEND}"
|
||||
|
||||
RESTRICT+=" test"
|
||||
|
||||
pkg_pretend() {
|
||||
ecm_pkg_pretend
|
||||
|
||||
if ! has_version sci-mathematics/maxima && ! has_version sci-mathematics/octave && \
|
||||
! use analitza && ! use julia && ! use lua && ! use python && ! use qalculate && ! use R; then
|
||||
elog "You have decided to build ${PN} with no backend."
|
||||
elog "To have this application functional, please enable one of the backends via USE flag:"
|
||||
elog " analitza, lua, python, qalculate, R"
|
||||
elog "Alternatively, install one of these:"
|
||||
elog " # emerge sci-mathematics/maxima (bug #619534)"
|
||||
elog " # emerge sci-mathematics/octave"
|
||||
elog "Experimental available USE flag:"
|
||||
elog " julia (not stable, bug #613576)"
|
||||
elog
|
||||
fi
|
||||
|
||||
if ! has_version virtual/latex-base; then
|
||||
elog "For LaTeX support:"
|
||||
elog " # emerge virtual/latex-base"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
use python && python-single-r1_pkg_setup
|
||||
ecm_pkg_setup
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
use julia && addpredict /proc/self/mem # bug 602894
|
||||
|
||||
local mycmakeargs=(
|
||||
$(cmake_use_find_package analitza Analitza5)
|
||||
$(cmake_use_find_package julia Julia)
|
||||
$(cmake_use_find_package lua LuaJIT)
|
||||
$(cmake_use_find_package postscript LibSpectre)
|
||||
$(cmake_use_find_package python PythonLibs3)
|
||||
$(cmake_use_find_package qalculate Qalculate)
|
||||
$(cmake_use_find_package R R)
|
||||
)
|
||||
ecm_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user