sci-electronics/klayout: version bump 0.27.10

Signed-off-by: Andreas K. Hüttel <dilfridge@gentoo.org>

sci-electronics/klayout/Manifest

@@ -1,3 +1,2 @@
-DIST klayout-0.27.3.tar.gz 57274694 BLAKE2B 131791f7e978a5ffd344d1dab15d0d245d971855d34c995b4f86173f31853f71ec79d089cc2f80a10d318b108cb0f624c9610c9bf51f0bd88f2265e2d8871c97 SHA512 5f3a83cbbdc171acf200a90e4758942e7c3dd4ec66666576c6ecb041326e52a99222992e844d63f939650374a7493f542b1412ada714b6c0271103facb5acaa9
+DIST klayout-0.27.10.tar.gz 57428098 BLAKE2B 3f64ed6a65ec7d2732691594f50d02f160725a3306cd0d0593f8c2b5978d5cf76e004ed3347bb6e9d9473b8e0974bc04de101ec3bf168faf147e6c64c5f0bdcb SHA512 a637b0a0bd1eaa3c858c333791c5592bc8a4dc1db7413b83432d7bedce9ba7e1210c76086a4f39504bc23a11778a45370b86262c88daa579517e1dee940ecda7
 DIST klayout-0.27.7.tar.gz 57348398 BLAKE2B c717d1041e2b2f1ec4835db3861a8c7ff15d2cd703d3424d9219cb0fab06471a6838503c882b841be45c9e1b9280d1f7a099f9824c6e286940d3b44713927974 SHA512 f4b4f3f2216307df5dca3b9c9c4eee5b45e5811a3307f36d3ad759d33beb8cd83880485284492583b891ee8bbf2866cae0ce87b5c5971478d8ad8daad315bb09
-DIST klayout-0.27.tar.gz 56917189 BLAKE2B 41a66939d6d7a058f9dc1772ba152ff1c311b146f7e2b37da52447cbd7eacc35a26a5fec1516384619ab0680a145f82a120ee7ee2739a5c8e9648836afa07d13 SHA512 475e2d905bc75a13c924f6cd1d08b566ecde92a28ed6a32b1995452e0446d4c75f7856ce3af4430a3b39a3876a3817923a51f3675c5afb33f4ec749acf15e0b4

sci-electronics/klayout/klayout-0.27.10.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+RUBY_OPTIONAL=no
+USE_RUBY="ruby27"
+# note: define maximally ONE implementation here
+
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit toolchain-funcs python-single-r1 ruby-ng
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/klayoutmatthias/${PN}.git"
+	inherit git-r3
+	EGIT_CHECKOUT_DIR=${WORKDIR}/all/${P}
+else
+	SRC_URI="https://www.klayout.org/downloads/source/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
+HOMEPAGE="https://www.klayout.de/"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	dev-qt/designer:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	sys-libs/zlib
+	${PYTHON_DEPS}
+	$(ruby_implementations_depend)
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ruby-ng_pkg_setup
+}
+
+each_ruby_configure() {
+	tc-export CC CXX AR LD RANLIB
+	export CFLAGS CXXFLAGS
+	./build.sh \
+		-expert \
+		-dry-run \
+		-qmake "$EPREFIX/usr/$(get_libdir)/qt5/bin/qmake" \
+		-ruby "${RUBY}" \
+		-python "${PYTHON}" \
+		-build . \
+		-bin "${T}/bin" \
+		-rpath "$EPREFIX/usr/$(get_libdir)/klayout" \
+		-option "${MAKEOPTS}" \
+		-with-qtbinding \
+		-without-64bit-coord \
+		-qt5 || die "Configuration failed"
+}
+
+each_ruby_compile() {
+	emake all
+}
+
+each_ruby_install() {
+	emake install
+
+	cd "${T}/bin" || die
+
+	dodir "/usr/$(get_libdir)/klayout"
+	mv lib* lay_plugins db_plugins "${ED}/usr/$(get_libdir)/klayout/" || die
+
+	mkdir -p "${D}/$(python_get_sitedir)" || die
+	mv pymod/* "${D}/$(python_get_sitedir)/" || die
+	rmdir pymod || die
+
+	dobin *
+
+	python_optimize
+}