net-p2p/gtk-gnutella: add 1.2.3

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
This commit is contained in:
Hans de Graaff
2024-03-06 11:53:56 +01:00
parent 73ca936016
commit f8022c84ea
2 changed files with 94 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST gtk-gnutella-1.2.2.tar.gz 26708793 BLAKE2B 9b8c1600914f5679c017929afa6d1f508734b21d95231c15588c64d9b1e9185ddb82ee26478d5d5d34c715fd475ccfe1e65b4b96ed4acc271444d21317013630 SHA512 d4825bb765d9b73b24d1dc7238a31c5e78c9adb7c765b0b913d4fce1467fb3655ac3214381748bca20fd3e02345ba0583d591e2177299d5130951808cd7bd325
DIST gtk-gnutella-1.2.3.tar.gz 28346798 BLAKE2B a502ed7bc8cae8355df3c4b7f0e85c06076d9e6703060299f4b6d01680c0822a5269faa4854e6044134d9cc3f3819ea2a3a2fccdf2e44e49b357f29191271e55 SHA512 fbd7aa528aff95dfcfc4b4620fb0b788301e31286208accbb6eada93cc8ad83c4f7ed3275a5af6e91b49aebe6ba836b4094036e79602235d5fd6161ba797339a
@@ -0,0 +1,93 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit flag-o-matic strip-linguas toolchain-funcs
DESCRIPTION="GTK+ Gnutella client"
HOMEPAGE="https://gtk-gnutella.sourceforge.io/"
SRC_URI="https://github.com/gtk-gnutella/gtk-gnutella/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SLOT="0"
LICENSE="CC-BY-SA-4.0 GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="nls dbus ssl +gtk"
RDEPEND="
sys-libs/binutils-libs:=
dev-libs/glib:2
sys-libs/zlib
gtk? ( >=x11-libs/gtk+-2.2.1:2 )
dbus? ( >=sys-apps/dbus-0.35.2 )
ssl? ( >=net-libs/gnutls-2.2.5 )
nls? ( >=sys-devel/gettext-0.11.5 )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
src_prepare() {
filter-lto
strip-linguas -i po
echo "# Gentoo-selected LINGUAS" > po/LINGUAS
local ling
for ling in ${LINGUAS}; do
echo $ling >> po/LINGUAS
done
# bug #738504
sed -i -e 's|share/appdata|share/metainfo|g' extra_files/Makefile.SH || die
default
}
src_configure() {
# There is no option to turn off optimization through the build.sh
# script.
sed -i -e "s/Configure -Oder/Configure -Oder -Doptimize=none/" build.sh || die
# The build script does not support the equivalent --enable
# options so we must construct the configuration by hand.
local myconf
if ! use nls; then
myconf="${myconf} --disable-nls"
fi
if ! use dbus; then
myconf="${myconf} --disable-dbus"
fi
if ! use ssl; then
myconf="${myconf} --disable-gnutls"
fi
if use gtk; then
myconf="${myconf} --gtk2"
else
myconf="${myconf} --topless"
fi
./build.sh \
--configure-only \
--prefix="/usr" \
--cc="$(tc-getCC)" \
${myconf}
}
src_compile() {
# Build system is not parallel-safe, bug 500760
emake -j1 AR="$(tc-getAR) rc" NM="$(tc-getNM)"
}
src_install() {
dodir /usr/bin
emake INSTALL_PREFIX="${D}" install
dodoc AUTHORS ChangeLog README TODO
# Touch the symbols file into the future to avoid warnings from
# gtk-gnutella later on, since we will most likely strip the binary.
touch --date="next minute" "${D}/usr/lib/gtk-gnutella/gtk-gnutella.nm" || die
}