app-i18n/ibus-table: new upstream release

Signed-off-by: Akinori Hattori <hattya@gentoo.org>

app-i18n/ibus-table/Manifest

@@ -1,2 +1,3 @@
 DIST ibus-table-1.17.0.tar.gz 1545826 BLAKE2B 33890dffca38c76513f49a54419805aff1b13e79b069cdb655401a44eeb44201c4cc60a29e9b341bd25dc9431a6e15e0481dc7cbd3ad3f02ae07cfcc6f811c81 SHA512 2df316dfe34eca80d9d4f843a92f3452a939cd14bca3bfa6c021b0bc6b759676711fefba68b9bf10dfe48c2f82890452e9ae015986b520281998f4d08f2e763b
 DIST ibus-table-1.17.1.tar.gz 1546204 BLAKE2B e6aa8fb66af08f504c032f9950c52ffc4eefd1633dfdb49e7c7eb4e38f9c103be1e845927a61418a1c1e028dcdf50ad8bd6d64640697506c15d82f7021282e64 SHA512 67168bb301820fa006208a15c3dc0f72480f8dd7bcd4097f0ee837fa44a1d04d68760f3061d655ec8a19ccb60aee2d6fd54bb5dd13668c61edb38b6e46f1b9ff
+DIST ibus-table-1.17.2.tar.gz 1547063 BLAKE2B 6ac449f48cc169c64df3e4c2d9ceac36378ee0303809c811eacd8e58c6c41a47af6bbe6176a544fd799faa9787b2d68589181aef3d07ef65d82159150ef8dc10 SHA512 f3b257d80e3e6a92b2aa3f48d43e104aae9a015b00bf7f6c1c146e5ea2c0d8d0bd7187225fdbb0c0ccb548c5659dfd05ea0137fa7306ceab82169b11cd8c2419

app-i18n/ibus-table/ibus-table-1.17.2.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Tables engines for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://github.com/kaio/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	python_fix_shebang .
+
+	default
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}