net-misc/nextcloud-client: 2.3.1 bump, bug #614878

Package-Manager: Portage-2.3.5, Repoman-2.3.2

net-misc/nextcloud-client/Manifest

@@ -1,2 +1,4 @@
 DIST nextcloud-client-2.2.4.tar.gz 642472 SHA256 55a16505c8551cb8e6af5d2f570b6d4384f33a75a79810864e1d4555d53dedf9 SHA512 646e624335cc11ac862b1b58ceb36aa8264f2db6ed586ae473b7522a5fdab7e30f196c1680f8dcf70af3b204374488e3bd589bb41669f9abcd9509d2293afc3f WHIRLPOOL 1bf627732492726fbb8394c2c88dcef667b8079a8923c906a58bd2039b14b27e76224ceb8d08654806d7f55f966b949c338ec759746acb90e023adc608d659da
+DIST nextcloud-client-2.3.1.tar.gz 654810 SHA256 5fc6f9f981d68110982ab006cdf9d68caa0c59015e57f4491b9a705fb6c83dd6 SHA512 f8210c8cc08e0bfb80e63b18af305c2a8e2309f673caca5bc748c130d960d444ab2db3fad3e43dbfffbe072748c85e15a50d0ebe1fd491dec7553ac8d9552cfe WHIRLPOOL 5a38a708647758ddb54d7d47dd30a71e59b03c3c45e6cfd9ac218c013da9dfc56d07b247982056f58e083d82c138576679525d994665717c739cc9f5cdd0238b
 DIST owncloudclient-2.2.4.tar.xz 12216896 SHA256 f313534f7cdae686beeaa6670d9e3586a627ce78b67cab6e42a448a675d9e7d3 SHA512 5bc5273c90ab63c411e58d1fe13636f6b5977c28470efe53296a71541aaa63af99001cb630adaee99b9b81a8b56fe0f66c337319464ab950dd6eac4cdd53f951 WHIRLPOOL 18aa5076049f9cdfbafa58454937b7fc4c38a5405b6e1375d762d88bbfae92b813cd2ec88a4e4108012137c94908894821575d3f6d2bf694e35d734f2b8fbd37
+DIST owncloudclient-2.3.1.tar.xz 12260696 SHA256 93143752234a0bc4c9798b69d8239996d92130eecdc1d93b75e3d49b899f3914 SHA512 2dec3d4b452faca32e15c1a461d3fec97fc1c2e85bbfe2cb02035371a5426b8458be1382ed6b4a1102a4f38241580c3d49980ea388344365297a4a84f8dc9add WHIRLPOOL 49abeb9b9843a024338cd2d7c3a87625f7cd4f832db03513dc4d7b0d5d1908a5691d6f1e7b7437175084c30a5e3e18d837785afa5647971fdcb8e963db2d54b5

net-misc/nextcloud-client/nextcloud-client-2.3.1.ebuild

@@ -0,0 +1,104 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Nextcloud themed desktop client"
+HOMEPAGE="https://github.com/nextcloud/client_theming"
+SRC_URI="http://download.owncloud.com/desktop/stable/owncloudclient-${PV}.tar.xz
+	https://github.com/nextcloud/client_theming/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin nautilus samba +sftp test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwebkit:5
+	sys-fs/inotify-tools
+	virtual/libiconv
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/ocsync
+	!net-misc/owncloud-client
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)
+"
+
+S=${WORKDIR}/client_theming-${PV}
+
+src_unpack() {
+	default
+
+	rmdir "${S}"/client || die
+	mv "${WORKDIR}"/owncloudclient-${PV} "${S}"/client \
+		|| die
+}
+
+src_prepare() {
+	CMAKE_USE_DIR="${S}"/client
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" client/test/test*.cpp || die
+	# Fix icon name
+	sed -e "/^Icon.*=/s/@APPLICATION_EXECUTABLE@/Nextcloud/" \
+		-i client/mirall.desktop.in || die
+
+	if ! use nautilus; then
+		pushd client/shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+
+	default
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DWITH_ICONV=ON
+		-DWITH_DOC=$(usex doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DBUILD_WITH_QT4=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libsmbclient=$(usex !samba)
+		-DCMAKE_DISABLE_FIND_PACKAGE_LibSSH=$(usex !sftp)
+		-DUNIT_TESTING=$(usex test)
+		-DOEM_THEME_DIR="${S}"/nextcloudtheme
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}