dev-python/quart: Bump to 0.19.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/quart/Manifest

@@ -1 +1,2 @@
 DIST quart-0.19.5.gh.tar.gz 494282 BLAKE2B d908638a00d67798dc71bb84ab51b2b35ee55c1b16ba88781642a1b64b70e0206e33c4e61cb397451969d0edde593ac2639ce8000838750e312b1ef47b8b154a SHA512 a764f50b19c84f7b4cf368488a703c726b2e98785cc7e0c15de0c3293f764658bb6e1489be53bb03ca135ccd847383424fdba8706383a45f406c39fdceb26d71
+DIST quart-0.19.6.gh.tar.gz 747457 BLAKE2B 2912e8e951ad94e8f86e553ee8fac2d3ea679f71be54ff6638aa36d3d3027b48de47994a2f264b3cee69b483ffe4e153c7ea0080b8f6904a2ebaddce2fbede96 SHA512 2a28a36638052c26265122771936dbe8a12332c8abe177a9addafc71b4a0987c864c26f73160492d6e849a5b0a576346ac24c961c5e461afd11981c45aecbcd7

dev-python/quart/quart-0.19.6.ebuild

@@ -0,0 +1,50 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python ASGI web microframework with the same API as Flask"
+HOMEPAGE="
+	https://github.com/pallets/quart/
+	https://pypi.org/project/Quart/
+"
+# no tests in sdist as of 0.19.4
+SRC_URI="
+	https://github.com/pallets/quart/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/aiofiles[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.6[${PYTHON_USEDEP}]
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/hypercorn-0.11.2[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/markupsafe[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-3.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -p asyncio
+}