gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/google-api-core: Bump to 2.11.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-06-15 05:59:55 +02:00
parent a31b2ef2e5
commit f72fa2b59d
2 changed files with 75 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/google-api-core/Manifest
View File

@@ -1 +1,2 @@
DIST python-api-core-2.11.0.gh.tar.gz 187535 BLAKE2B e8029b6344b572e1dcc8455b95f3ee63c8d3684f0c8807793e4e6ba2dd0179c939f183144085c2b94a29b8a1ae0e39aeffceb632988702806665ec39c51e3ce5 SHA512 798ff3970027d7ce60dcb62a88d395ebf00454f902fda4f272fc240b9ec104af112dd9de479fb6761990c48931c8ccd8c5223a1b2b5fa44823cabac862efdba8
DIST python-api-core-2.11.1.gh.tar.gz 187982 BLAKE2B 095b96b50f0723543acf32e4db092a8b24eccf68088229668f7f36aa0d29f66905ea8c43d7ca4a4ee4179664b6bb63c45e4619d621a99f8c2a81a4b3dd61c25e SHA512 a2ca8a2a136fd29999662201af462b45da07c0e4d124649bba12d0564c595ebf02bd398354394d7eb4116c875b2c72b29280ee5a770a6773254accc979eacbbe

74
dev-python/google-api-core/google-api-core-2.11.1.ebuild Normal file
View File

@@ -0,0 +1,74 @@
# Copyright 2020-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1
MY_P=python-api-core-${PV}
DESCRIPTION="Core Library for Google Client Libraries"
HOMEPAGE="
https://github.com/googleapis/python-api-core/
https://pypi.org/project/google-api-core/
https://googleapis.dev/python/google-api-core/latest/index.html
"
SRC_URI="
https://github.com/googleapis/python-api-core/archive/v${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
RDEPEND="
>=dev-python/googleapis-common-protos-1.56.2[${PYTHON_USEDEP}]
>=dev-python/google-auth-1.25.0[${PYTHON_USEDEP}]
>=dev-python/protobuf-python-3.19.5[${PYTHON_USEDEP}]
>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
<dev-python/requests-3[${PYTHON_USEDEP}]
!dev-python/namespace-google
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/proto-plus[${PYTHON_USEDEP}]
dev-python/rsa[${PYTHON_USEDEP}]
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
EPYTEST_DESELECT=(
# failing due to missing grpcio-status
tests/asyncio/test_grpc_helpers_async.py::test_wrap_unary_errors
tests/asyncio/test_grpc_helpers_async.py::test_wrap_stream_errors_raised
tests/asyncio/test_grpc_helpers_async.py::test_wrap_stream_errors_read
tests/asyncio/test_grpc_helpers_async.py::test_wrap_stream_errors_aiter
tests/asyncio/test_grpc_helpers_async.py::test_wrap_stream_errors_write
tests/unit/test_grpc_helpers.py::test_wrap_unary_errors
tests/unit/test_grpc_helpers.py::test_wrap_stream_errors_invocation
tests/unit/test_grpc_helpers.py::test_wrap_stream_errors_iterator_initialization
tests/unit/test_grpc_helpers.py::test_wrap_stream_errors_during_iteration
)
python_compile() {
distutils-r1_python_compile
find "${BUILD_DIR}" -name '*.pth' -delete || die
}
src_test() {
rm -r google || die
distutils-r1_src_test
}
python_test() {
distutils_write_namespace google
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p asyncio tests
}