games-emulation/dosbox-staging: add 0.80.0

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

games-emulation/dosbox-staging/Manifest

@@ -1 +1,2 @@
 DIST dosbox-staging-0.79.1.tar.gz 3280884 BLAKE2B 48fd371df026392d59db2c9874f81b772b6595e2471a7ad1200e27e94fc87892f8e1c51288c1b0a430d8c3260535e35a00025047248551569f402b32a1ca3cf8 SHA512 6d7212229b58936cd1c4382f5e5cad45066e92f6a5b3bb2e97177ff7122dd527496a16dcefbfa84c3ad031d805c804c7872ec6eeaef9d695b0b8c4309f58acc7
+DIST dosbox-staging-0.80.0.tar.gz 3871598 BLAKE2B 59cb6515f17b9a661f5e9d7787b01ecef4fe047dfd0ca4573cc12c73af1f9fe433f4c20a1c42e1fcd259c31af3922738c057aa64fc777a513a7881a86436a1fa SHA512 aed548df29d5d4aa6593f0b589d7548caaf02be31668dc2c6bcbb0eb324a73d9344ce471a8449e90706b379ed6794e6584e5ebc6b3628274f5ec6667c14a3d8a

games-emulation/dosbox-staging/dosbox-staging-0.80.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit meson xdg
+
+DESCRIPTION="Modernized DOSBox soft-fork"
+HOMEPAGE="https://dosbox-staging.github.io/"
+SRC_URI="https://github.com/dosbox-staging/dosbox-staging/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+alsa debug dynrec +fluidsynth mt-32 network opengl screenshot slirp test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	debug? ( sys-libs/ncurses:0= )
+	fluidsynth? (
+		media-sound/fluid-soundfont
+		media-sound/fluidsynth
+	)
+	mt-32? ( media-libs/munt-mt32emu )
+	network? ( media-libs/sdl2-net )
+	opengl? ( virtual/opengl )
+	screenshot? ( media-libs/sdl2-image )
+	slirp? ( net-libs/libslirp )
+	media-libs/iir1
+	media-libs/libpng:0=
+	media-libs/libsdl2[joystick,opengl?,video,X]
+	media-libs/opusfile
+	media-libs/speexdsp
+	sys-libs/zlib
+	!games-emulation/dosbox"
+DEPEND="${RDEPEND}"
+BDEPEND="test? ( dev-cpp/gtest )"
+
+DOCS=( AUTHORS README THANKS )
+
+src_prepare() {
+	default
+
+	# We do not have default.sf2, use actual name from fluid-soundfont
+	sed -e "s/default.sf2/FluidR3_GM.sf2/" \
+		-i src/midi/midi_fluidsynth.cpp || die
+
+	# Disable license and docs install (handled by ebuild)
+	sed -e "/licenses_dir\|doc_dir/d" -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use alsa use_alsa)
+		$(meson_use debug)
+		-Ddynamic_core=$(usex dynrec dynrec dyn-x86)
+		$(meson_use fluidsynth use_fluidsynth)
+		$(meson_use mt-32 use_mt32emu)
+		$(meson_use network use_sdl2_net)
+		$(meson_use opengl use_opengl)
+		$(meson_use screenshot use_sdl2_image)
+		$(meson_use slirp use_slirp)
+		$(meson_feature test unit_tests)
+	)
+	meson_src_configure
+}

games-emulation/dosbox-staging/metadata.xml

@@ -10,6 +10,7 @@
 		<flag name="fluidsynth">use <pkg>media-sound/fluidsynth</pkg> for MIDI emulation</flag>
 		<flag name="mt-32">use <pkg>media-libs/munt-mt32emu</pkg> for MT-32 emulation</flag>
 		<flag name="network">Enable networking features (modem, ipx)</flag>
+		<flag name="screenshot">Enable screenshots of rendered output using <pkg>media-libs/sdl2-image</pkg></flag>
 		<flag name="slirp">Enable Ethernet emulation using <pkg>net-libs/libslirp</pkg></flag>
 	</use>
 	<upstream>