gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 6.64.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-01-23 07:56:12 +01:00
parent f6b5c4eca4
commit f706b06f88
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -4,3 +4,4 @@ DIST hypothesis-6.61.3.gh.tar.gz 9339977 BLAKE2B 2bd7f2828563694f678eacc3537e920
DIST hypothesis-6.62.0.gh.tar.gz 9341805 BLAKE2B 44a7f9a15f93e402405226d40293ea29954b1a85df02c18386aa0eebc72d973005402664df1f0594d30b25e2f4c43ed56c4a79ab0ad6627196ff5661ee6fff0a SHA512 5ccc098ca738f634972c210ba2cbf02f4f4f909ac7f963a0e761fe2868679854d1b51036b09c61f8cabff000b9f14221ead43740a9f17538138f67be9bd04815
DIST hypothesis-6.62.1.gh.tar.gz 9342261 BLAKE2B 68ffa2294e667e1182ddc96d2b2595723ae38077a63c8f5c8d45ed232536f6749c15912ca9fa61280e9564ac117fc8f94555a564aef5bdfcb8f9bdc38faa8c3e SHA512 1f886de0ae1c4e3371a60e45f00f265542cefa89ce1a109f794ceff3eaa648e2faf566b86b0921e5741b5d8b8d285169387426d8a069410e86642a95380e312e
DIST hypothesis-6.63.0.gh.tar.gz 9342417 BLAKE2B edd4795c9fc4e254fda89fff7554965f350c9dcb738095f4ddb1da16a169ea0b72a52ce4321543efa97f69382a76307d622c37e81e3372867e57ad9ef2060d0b SHA512 9e863d72abea9431d027fbffe39107bb95dc9e80c423d2a69b039489119841fbcc99ddf54248b5d8a797bccdeb450760101862baa3be113c7715430591d054a6
DIST hypothesis-6.64.0.gh.tar.gz 9345246 BLAKE2B 2ee9a14e84bb72a8248c28096a31b4873f51c121b6446cbcd5d2831418f769ba464d2aead1a52f3da23e640f46e05e7af8927c65113fc7fb3ea59086324c2210 SHA512 4da49b4ab62e9c90770c098653d3b43bbf3fbf8b7aca27546ae2ce0be7923cbabe240a73d124e4e48fc9b8a3e06d31e336b18b875b743992e175acfe2cddd270

77
dev-python/hypothesis/hypothesis-6.64.0.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{9..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/requests-toolbelt-0.10.1
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}