dev-python/rapidfuzz: Bump to 3.6.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/rapidfuzz/Manifest

@@ -1 +1,2 @@
 DIST rapidfuzz-3.5.2.tar.gz 1524315 BLAKE2B 0877a38f3d4229b12944ede688891f5cc401ac644439d93e02a424370ab0e64eebab283de8d921a6e51ff622e425f8ba3b4f13f4eb16f0764440d9c62eca2c50 SHA512 65f7041558c1932ca916faa3c165f62694c7b261d626eb87579e25cd544e9be5bf6da073b6ee621ba2eba4662183315836acb0deda9bb33c1dc927e692438754
+DIST rapidfuzz-3.6.0.tar.gz 1560666 BLAKE2B b0e36a63b68ab2cfdd79c551a9550f6eb763433de4e7f38a81fe8cf05fa2c84a2299f28c2ebeeccfe6ac6d003b181cb810cfb14b578c5b8eade6d77918485278 SHA512 3cd4b85ecd4b6d2fe95e16a7db6d9e936ca82ad8e17a9543609ecd50c14c9a74a3ef6454b1f7a077be0138a14f585ec0729c7e84725fb985595f403dd2705ef2

dev-python/rapidfuzz/rapidfuzz-3.6.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/maxbachmann/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-3.0.0
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	dev-python/rapidfuzz-capi[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+	# remove bundled libraries
+	rm -r extern || die
+	# force recythonization
+	find src -name '*.cxx' -delete || die
+
+	distutils-r1_src_prepare
+
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# scikit-build is broken and reuses the same build
+	# https://github.com/scikit-build/scikit-build/issues/633
+	rm -r _skbuild || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p xdist -n "$(makeopts_jobs)" --dist=worksteal
+}