kde-apps/marble: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2020-12-12 18:57:08 +01:00
parent 9e638e04d7
commit f6fd39bf7c
3 changed files with 100 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST marble-20.08.3.tar.xz 52191936 BLAKE2B a7990d76d6df1333b5beac62d82e4e10ad55fa2513f579d4d169bd24e54e8d2f4132847d9544dcbeb1205b4bedcd193792332434c64c97cf9eb1180f6bad9b05 SHA512 0bffe97a14fe74300eef8c94a3d14217abba6602fef86e07c799d52970e37047576defd4baeaebe9171ff3915f35c0a64ca2e46d233fde834c8bd5dc3f15ebce
DIST marble-20.12.0.tar.xz 52213632 BLAKE2B 38f58f66a353dcf05c06da2d801a510470f7099efdae78056f85140ecd59ea7df414f58a113b6afad63789e78cba7ca3baeded099facedd551b3e1f5a8f862f4 SHA512 c2ec32136cec0500f917abf0c5e2c60a4b04666d72fd1bcd2453f6de70c7bda356f18c60f0b48bb29309001203a720e5acbd1f5efe3baf242055303bf3f730f0
+98
View File
@@ -0,0 +1,98 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
ECM_HANDBOOK="optional" # see src/apps/marble-kde/CMakeLists.txt
ECM_TEST="forceoptional"
KFMIN=5.75.0
QTMIN=5.15.1
VIRTUALX_REQUIRED="test"
inherit ecm kde.org
DESCRIPTION="Virtual Globe and World Atlas to learn more about Earth"
HOMEPAGE="https://marble.kde.org/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5/$(ver_cut 1-2)"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="aprs +dbus designer +geolocation gps +kde nls +pbf phonon shapefile +webengine"
# FIXME (new package): libwlocate, WLAN-based geolocation
BDEPEND="
aprs? ( dev-lang/perl )
nls? ( >=dev-qt/linguist-tools-${QTMIN}:5 )
"
DEPEND="
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdeclarative-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5
>=dev-qt/qtsvg-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
sys-libs/zlib
aprs? ( >=dev-qt/qtserialport-${QTMIN}:5 )
dbus? ( >=dev-qt/qtdbus-${QTMIN}:5 )
designer? ( >=dev-qt/designer-${QTMIN}:5 )
geolocation? ( >=dev-qt/qtpositioning-${QTMIN}:5 )
gps? ( sci-geosciences/gpsd )
kde? (
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knewstuff-${KFMIN}:5
>=kde-frameworks/kparts-${KFMIN}:5
>=kde-frameworks/krunner-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwallet-${KFMIN}:5
)
pbf? ( dev-libs/protobuf:= )
phonon? ( >=media-libs/phonon-4.11.0 )
shapefile? ( sci-libs/shapelib:= )
webengine? (
>=dev-qt/qtwebchannel-${QTMIN}:5
>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
)
"
RDEPEND="${DEPEND}"
# bug 588320
RESTRICT+=" test"
src_prepare() {
ecm_src_prepare
rm -rf src/3rdparty/zlib || die "Failed to remove bundled libs"
use kde && cmake_run_in src/apps cmake_comment_add_subdirectory marble-qt
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package aprs Perl)
$(cmake_use_find_package geolocation Qt5Positioning)
-DBUILD_MARBLE_TESTS=$(usex test)
-DWITH_DESIGNER_PLUGIN=$(usex designer)
-DWITH_libgps=$(usex gps)
-DWITH_KF5=$(usex kde)
$(cmake_use_find_package pbf Protobuf)
-DWITH_Phonon4Qt5=$(usex phonon)
-DWITH_libshp=$(usex shapefile)
$(cmake_use_find_package webengine Qt5WebEngine)
$(cmake_use_find_package webengine Qt5WebEngineWidgets)
-DWITH_libwlocate=OFF
# bug 608890
-DKDE_INSTALL_CONFDIR="/etc/xdg"
)
if use kde; then
ecm_src_configure
else
cmake_src_configure
fi
}
+1
View File
@@ -9,6 +9,7 @@
<flag name="aprs">Enable support for APRS data sources</flag>
<flag name="designer">Install plugin for <pkg>dev-qt/designer</pkg></flag>
<flag name="geolocation">Enable position information via <pkg>dev-qt/qtpositioning</pkg></flag>
<flag name="pbf">Enable OpenStreetMap PBF file support via <pkg>dev-libs/protobuf</pkg></flag>
<flag name="phonon">Enable sound support via <pkg>media-libs/phonon</pkg></flag>
<flag name="shapefile">Enable support for ESRI shapefiles</flag>
<flag name="webengine">Use <pkg>dev-qt/qtwebengine</pkg> for embedded web browser</flag>