app-editors/texworks: add 0.6.11

Closes: https://bugs.gentoo.org/973738
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

app-editors/texworks/Manifest

@@ -1 +1,2 @@
 DIST texworks-0.6.10.tar.gz 11479436 BLAKE2B a6b251068c42d3ff68dfb3e5c69348abc984ace1fa9c25b3b815d22f4294931a67697ebb7abb708709be7333aee90495fdf854dea0b6625963ba35902b6aa7e0 SHA512 3f8ec187b8d6dd5f62c84cb93ac6b8d9369a8b53525518c47504fba0d1353af90d02a4b68eb38e8f623dce2f2cceae33b20917be7793f0e058864ccea7a2f8b6
+DIST texworks-0.6.11.tar.gz 11509961 BLAKE2B 376d6ab647ee3610088ddd41e0cc3aeb147519dbadee6b8540127f87d191834ec9a7685bf240e911259ec43ef50562b4db45e20cd1b8bd1ecd99d21d61d22815 SHA512 f281001fa28bb9b9d4d633d234b844f94b1d019dcdb8f9ea6794d5baa4844dffb663a43cc84db7bc0f2f60babcd0562c752e0ce198d1a2241ac58754f1dd962e

app-editors/texworks/texworks-0.6.11.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} )
+PYTHON_COMPAT=( python3_{11..14} )
+CMAKE_REMOVE_MODULES_LIST=( FindLua )
+inherit lua-single python-single-r1 cmake xdg
+
+DESCRIPTION="Simple interface for working with TeX documents"
+HOMEPAGE="https://tug.org/texworks/"
+SRC_URI="https://github.com/TeXworks/texworks/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-release-${PV}"
+
+LICENSE="GPL-2+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="lua python test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	app-text/hunspell:=
+	app-text/poppler[qt6]
+	dev-qt/qt5compat:6
+	dev-qt/qtbase:6[concurrent,dbus,gui,widgets,xml]
+	dev-qt/qtdeclarative:6
+	dev-qt/qttools:6[widgets]
+	virtual/zlib:=
+	lua? ( ${LUA_DEPS} )
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.6.10-cmake_lua_version.patch
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-Wno-dev
+		-DPREFER_BUNDLED_SYNCTEX=ON
+		-DWITH_LUA=$(usex lua)
+		-DWITH_PYTHON=$(usex python)
+		-DWITH_TESTS=$(usex test)
+		-DTeXworks_PLUGIN_DIR="/usr/$(get_libdir)/texworks"
+		-DTeXworks_DOCS_DIR="/share/doc/${PF}"
+		-DQTPDF_VIEWER=ON
+		-DBUILD_SHARED_PLUGINS=ON
+		-DQT_DEFAULT_MAJOR_VERSION=6
+		-DTW_BUILD_ID="Gentoo official package"
+	)
+
+	use lua && mycmakeargs+=( -DLUA_VERSION="$(lua_get_version)" )
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	cmake_src_test
+}