dev-python/sentry-sdk: Bump to 1.5.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/sentry-sdk/Manifest

@@ -1,2 +1,3 @@
 DIST sentry-sdk-1.5.6.gh.tar.gz 244568 BLAKE2B 5b9270787abaeadf2b5a15686aa07f60766cbe56c8c657801a88d6074ecab83fd38c3e0d1f0586cd8c8d5e36c5ffc97eec47998bf27bd9461ace9b8a83a2201d SHA512 628b8281e5c267a988730c0ddcb9348a43ce2cffe9b664619e6b5bc6ec4c0034898082b0b57bc2a8ea3100042a1bfb570ce4dd36a23ba412661ee902dfa41492
 DIST sentry-sdk-1.5.7.gh.tar.gz 244753 BLAKE2B 343c9439525f7609eb3c3962213c8c4b5493d2ace8143d3bb36cd4b13463f4548597f80ac49288d925e0f03a9675b1ed24744eb4cfa3dbe2700a19f2e03585d3 SHA512 8d5e41967387463ed50b4cd582ac0492905bb9cd8740054690f176b8ba07a095836141f4f23791a83909bdb18d4b006aeb0ff963c1663f97305bbdd819a2889a
+DIST sentry-sdk-1.5.8.gh.tar.gz 245374 BLAKE2B 0a94db069786813ce38346d50c51173cef5a47099232d56ecc561ebaf7e9ff3ef1063f964370aaf0f184ec02af7652db59153fa1bf3425e6c75c0a4c73c4ede2 SHA512 992cebceb9b3b2a861b6f084a1ae88f93a8cf740b8f0407550c31af9a9332afdeeb6e64d0dd29b2f80ac1cdade942ada90756c6fbc3373f3ee1948b9d037b59b

dev-python/sentry-sdk/sentry-sdk-1.5.8.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="https://sentry.io/ https://pypi.org/project/sentry-sdk/"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/eventlet[${PYTHON_USEDEP}]
+		' python3_{8..9})
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# tests require Internet access
+	tests/integrations/httpx/test_httpx.py
+	tests/integrations/requests/test_requests.py
+	tests/integrations/stdlib/test_httplib.py
+	# wtf is it supposed to do?!
+	tests/integrations/gcp/test_gcp.py
+	# broken by rq-1.10.1 (optional dep)
+	tests/integrations/rq/test_rq.py
+	# fastapi is not packaged
+	tests/integrations/asgi/test_fastapi.py
+)
+
+EPYTEST_DESELECT=(
+	# hangs
+	'tests/test_transport.py::test_transport_works'
+	# TODO
+	'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+	tests/test_client.py::test_databag_depth_stripping
+	tests/test_client.py::test_databag_string_stripping
+	tests/test_client.py::test_databag_breadth_stripping
+	tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/asgi/test_asgi.py::test_websocket
+	# incompatible version?
+	tests/integrations/falcon/test_falcon.py
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_too_large_event_truncated
+	# test_circular_references: apparently fragile
+	'tests/integrations/threading/test_threading.py::test_circular_references'
+	# test for new feature, fails with IndexError
+	tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	# TODO
+	tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+)