net-libs/libqmi: Version bump to 1.30.6

Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Matt Turner
2022-04-28 08:31:06 -07:00
parent 7199cc1564
commit f6a3b4edb1
2 changed files with 50 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST libqmi-1.30.4.tar.xz 1241912 BLAKE2B 561a2d4afd1b65955176490337e4f2335b0468010f0af546ea6026441224fa2713c2e7ed6aab958cb2657755247b75529d390155ef0bfc3aabba738755d28f23 SHA512 969c3e3fc8086c38e9192070eca155f5309947cdd1cfc9b883c27d80c6af2d069098a59e193bf1786260ab4fe4d05375555b5081dd173a88b33d84d409fa4a59
DIST libqmi-1.30.6.tar.xz 1242612 BLAKE2B 318af914b595f0442f7929be53c128dcd111e12913814bb52e683fff814b7aa00a32d40f8eae367db469a7adef6c146fb692d5908951cec4337f21e9a266a400 SHA512 6dc9819bb45063ea827b989e99e8e889db0ce6ebec62586003ea385bd54bd76f3e79d63e3f2b57e19da5f42ed87d7aa11aa024a805ec86a6b203981eb7922a76
+49
View File
@@ -0,0 +1,49 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
if [[ ${PV} == "9999" ]] ; then
inherit git-r3 autotools
EGIT_REPO_URI="https://gitlab.freedesktop.org/mobile-broadband/libqmi.git"
else
KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~x86"
SRC_URI="https://www.freedesktop.org/software/libqmi/${P}.tar.xz"
fi
DESCRIPTION="Qualcomm MSM (Mobile Station Modem) Interface (QMI) modem protocol library"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/libqmi/ https://gitlab.freedesktop.org/mobile-broadband/libqmi"
LICENSE="LGPL-2"
SLOT="0/5.8" # soname of libqmi-glib.so
IUSE="gtk-doc +mbim"
RDEPEND=">=dev-libs/glib-2.56
>=dev-libs/libgudev-232
mbim? ( >=net-libs/libmbim-1.18.0 )"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc )"
[[ ${PV} == "9999" ]] && BDEPEND+=" dev-util/gtk-doc" #469214
src_prepare() {
default
[[ ${PV} == "9999" ]] && eautoreconf
}
src_configure() {
local myconf=(
--disable-Werror
--disable-static
--disable-qrtr # libqrtr-glib not packaged
$(use_enable mbim mbim-qmux)
$(use_enable gtk-doc)
)
econf "${myconf[@]}"
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
}