gnome-base/gnome-flashback: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

gnome-base/gnome-flashback/Manifest

@@ -1 +1,2 @@
 DIST gnome-flashback-3.36.4.tar.xz 826568 BLAKE2B 6625b3a2d90649b9476d6340295b3cf8960f76908c23d75fe7b2a886d1a5c6a587bc8cb31ab866a40f2250b67d154a080f27534aaa11e822d901fc1cac0687af SHA512 6c1b910872530a86d6fb477ad55c8c44cbe5ef958073e2c675d95b9b4dbf9aab0d0a3b3cdae2daebbe3dad8a83c53ffe0604e12282864bfdee33402e119eff32
+DIST gnome-flashback-3.40.0.tar.xz 857104 BLAKE2B 41711edc4687682dd48134e452297bef7d0c4db93532bfd4bd49f19f2f01eab7c887b584f412384057e8a2b65a937446a108df0c4cfd811085c161a212e19355 SHA512 b938d12c437926e64567388b1a97350b76883cf91c009c1f57d4963321497ebdf69b094c7d88a86e5bf805930b88ff2637e522ac4f9981a391206a03d23a521e

gnome-base/gnome-flashback/gnome-flashback-3.40.0.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome2 toolchain-funcs
+
+DESCRIPTION="GNOME Flashback session"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-flashback/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="elogind systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=x11-libs/gdk-pixbuf-2.32.2:2
+	>=x11-libs/gtk+-3.22.0:3[X]
+	>=gnome-base/gnome-desktop-3.12.0:3=
+	>=gnome-base/gnome-panel-3.35.2
+	>=media-libs/libcanberra-0.13[gtk3]
+	>=dev-libs/glib-2.67.3:2
+	>=gnome-base/gsettings-desktop-schemas-3.31.0
+	>=sys-auth/polkit-0.97
+	>=app-i18n/ibus-1.5.2
+	>=sys-power/upower-0.99.0:=
+	>=x11-libs/libXrandr-1.5.0
+	>=x11-libs/libXxf86vm-1.1.4
+	x11-libs/libxcb
+	x11-libs/libX11
+	gnome-base/gdm
+	elogind? ( >=sys-auth/elogind-230 )
+	systemd? ( >=sys-apps/systemd-230:= )
+	net-wireless/gnome-bluetooth
+	x11-libs/libXext
+	>=x11-libs/libXi-1.6.0
+	x11-libs/pango
+	x11-libs/libxkbfile
+	x11-misc/xkeyboard-config
+	x11-libs/libXfixes
+	media-sound/pulseaudio[glib]
+	sys-libs/pam
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+" # autoconf-archive for eautoreconf
+RDEPEND="${RDEPEND}
+	x11-wm/metacity
+	gnome-base/gnome-panel
+	gnome-base/gnome-settings-daemon
+"
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		--without-compiz-session
+		$(use_enable systemd systemd-session)
+	)
+
+	# Below elogind DESKTOP_* and SCREENSAVER_* pkg-config calls need to match up with
+	# what upstream has each version (libsystemd replaced with libelogind). Explicit
+	# per-version die to force a manual recheck. Only update the explicit version if the
+	# "PKG_CHECK_MODULES([MENU/SCREENSAVER], ...)" blocks did not change; otherwise adjust
+	# elogind conditional block below accordingly first.
+	if ver_test ${PV} -ne 3.40.0; then
+		die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
+	fi
+
+	if use elogind; then
+		local pkgconfig="$(tc-getPKG_CONFIG)"
+		myconf+=(
+			DESKTOP_CFLAGS="$(${pkgconfig} --cflags glib-2.0 gio-2.0 gio-unix-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind x11)"
+			DESKTOP_LIBS="$(${pkgconfig} --libs glib-2.0 gio-2.0 gio-unix-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind x11)"
+			SCREENSAVER_CFLAGS="$(${pkgconfig} --cflags gdm gio-unix-2.0 glib-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind xxf86vm)"
+			SCREENSAVER_LIBS="$(${pkgconfig} --libs gdm gio-unix-2.0 glib-2.0 gnome-desktop-3.0 gtk+-3.0 libelogind xxf86vm)"
+		)
+	fi
+
+	gnome2_src_configure "${myconf[@]}"
+}