media-libs/sdl-mixer: Drop old 1.2.12_p20240525

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

media-libs/sdl-mixer/Manifest

@@ -1,2 +1 @@
-DIST sdl-mixer-1.2.12_p20240525.tar.gz 5835402 BLAKE2B 61238592251259c464f4e85be894f8ffcb8259c47bb56cddb0795fa4cd9f3fba2b431680b7a65ac9c2c87153f7e3bdde7b2496f5c536e55764e09c9450cdbea9 SHA512 1925b025c99a47d635f8a9a211712103c641a82c6d4e930b996de4eb1a08d5f5b1892dfd999924e0945d63ae4c59550ac112fbf7f8d76846d6ee54b1434e82a8
 DIST sdl-mixer-1.2.12_p20260511.tar.gz 5845445 BLAKE2B 3dd1b29ead493eb407e75a7655ea0d301df61c7e0da10251a815c394ed9fe2afe9aba5140418590247d34dedf4b6ef32d0e7f6382939a984ca19fb4ea1dbd684 SHA512 7d40255a10db327a0fc0b51e8f3e3ea9d6e8d7121ac0122a474edd3905d5a4dd658a1c86f05fa0a13b1e2a45f59f9748230655107f29f0edbab1fc6eb6213404

media-libs/sdl-mixer/sdl-mixer-1.2.12_p20240525.ebuild

@@ -1,114 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# Check SDL-1.2 branch for possible backports/new snapshots
-
-inherit multilib-minimal
-
-SDL_MIXER_COMMIT="ed76d39cda0735d26c14a3e4f4da996e420f6478"
-
-MY_PN=${PN/sdl-/SDL_}
-DESCRIPTION="Simple Direct Media Layer Mixer Library"
-HOMEPAGE="https://www.libsdl.org/projects/SDL_mixer/"
-SRC_URI="https://github.com/libsdl-org/SDL_mixer/archive/${SDL_MIXER_COMMIT}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}"/${MY_PN}-${SDL_MIXER_COMMIT}
-
-LICENSE="ZLIB"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~mips ppc ppc64 ~sparc x86"
-IUSE="flac fluidsynth mad midi mikmod mod modplug mp3 playtools smpeg static-libs timidity vorbis +wav"
-
-REQUIRED_USE="
-	midi? ( || ( timidity fluidsynth ) )
-	timidity? ( midi )
-	fluidsynth? ( midi )
-	mp3? ( || ( smpeg mad ) )
-	smpeg? ( mp3 )
-	mad? ( mp3 )
-	mod? ( || ( mikmod modplug ) )
-	mikmod? ( mod )
-	modplug? ( mod )
-"
-
-RDEPEND="
-	>=media-libs/libsdl-1.2.15-r4[${MULTILIB_USEDEP}]
-	flac? ( >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}] )
-	midi? (
-		fluidsynth? ( >=media-sound/fluidsynth-1.1.6-r1:=[${MULTILIB_USEDEP}] )
-		timidity? ( media-sound/timidity++ )
-	)
-	mod? (
-		mikmod? ( >=media-libs/libmikmod-3.3.6-r1[${MULTILIB_USEDEP}] )
-		modplug? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
-	)
-	mp3? (
-		mad? ( >=media-libs/libmad-0.15.1b-r8[${MULTILIB_USEDEP}] )
-		smpeg? ( >=media-libs/smpeg-0.4.4-r10[${MULTILIB_USEDEP}] )
-	)
-	playtools? (
-		!media-libs/sdl2-mixer[playtools]
-		!media-libs/sdl3-mixer[playtools]
-	)
-	vorbis? (
-		>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
-		>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
-	)
-"
-DEPEND="${RDEPEND}"
-
-multilib_src_configure() {
-	local myeconfargs=(
-		--disable-music-flac-shared
-		--disable-music-fluidsynth-shared
-		--disable-music-mod-shared
-		--disable-music-mp3-shared
-		--disable-music-ogg-shared
-
-		$(use_enable wav music-wave)
-		$(use_enable vorbis music-ogg)
-		$(use_enable mikmod music-mod)
-		$(use_enable modplug music-mod-modplug)
-		$(use_enable flac music-flac)
-		$(use_enable static-libs static)
-		$(use_enable smpeg music-mp3)
-		$(use_enable mad music-mp3-mad-gpl)
-		$(use_enable timidity music-timidity-midi)
-		$(use_enable fluidsynth music-fluidsynth-midi)
-
-		LIBMIKMOD_CONFIG="${EPREFIX}"/usr/bin/${CHOST}-libmikmod-config
-	)
-
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install
-	if multilib_is_native_abi && use playtools; then
-		emake DESTDIR="${D}" install-bin
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc CHANGES README
-	find "${ED}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
-	# bug 412035
-	# https://bugs.gentoo.org/show_bug.cgi?id=412035
-	if use midi ; then
-		if use fluidsynth; then
-			ewarn "FluidSynth support requires you to set the SDL_SOUNDFONTS"
-			ewarn "environment variable to the location of a SoundFont file"
-			ewarn "unless the game or application happens to do this for you."
-
-			if use timidity; then
-				ewarn "Failing to do so will result in Timidity being used instead."
-			else
-				ewarn "Failing to do so will result in silence."
-			fi
-		fi
-	fi
-}