dev-util/pkgdev: add 0.2.15

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-util/pkgdev/Manifest

@@ -1,2 +1,3 @@
 DIST pkgdev-0.2.12.tar.gz 87765 BLAKE2B 023c74d8563708d3601489a7df6c3da580ba3388f57ef31f52becf29e1d12725448058a3b237c733a365cbdc2d58523aed199f4ea6888fd96f50c59eca019a9b SHA512 3346b68585a8b5ad24293209fa312816d26e9b11e52135ab6866e993cafd28335d91eac66979cca04470181e4185145df8e0af0f2b98eb06c99ac46f19163c4c
 DIST pkgdev-0.2.14.tar.gz 88980 BLAKE2B 781dcedec3fa38a52210869ba5f50fdc051eb46bea8593636cbc877611f34364e89d4f943377f60eed81798ba4c097b7f5f8a95bbddcd61aa385866278ebaa18 SHA512 47c7ad2286c89b12661b605cd9032b5b27e497c25aef102cd62141b85a608f923b61eed9023784dc9b7eab1e218fc463f533b03f6f0f2bdb7b9456350988aab0
+DIST pkgdev-0.2.15.tar.gz 90194 BLAKE2B b92eb56d4bf8b7ae4aecfc042f74be21579d379a5fe3351d7f2e4b09c221a354c5a7f919f140d14e70d556da00a34758db8824a96aeaa489e6e136c1da5a06a2 SHA512 a165a5d4040a7652f63d4f7f8d6a6e4ca2f0ddb9aae8f6af8f9f0420f5cafcd071648e9ba162f87209749724c0ee062f9b84c3d11244a471a00a778205f1d10e

dev-util/pkgdev/pkgdev-0.2.15.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{11..14} )
+inherit distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_BRANCH="main"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgdev.git
+		https://github.com/pkgcore/pkgdev.git"
+	inherit git-r3
+else
+	inherit pypi
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Collection of tools for Gentoo development"
+HOMEPAGE="https://github.com/pkgcore/pkgdev"
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="doc"
+
+if [[ ${PV} == *9999 ]] ; then
+	RDEPEND="
+		~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		~dev-util/pkgcheck-9999[${PYTHON_USEDEP}]
+		~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]
+	"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.11.0[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.12.30[${PYTHON_USEDEP}]
+		>=dev-util/pkgcheck-0.10.36[${PYTHON_USEDEP}]
+	"
+fi
+
+RDEPEND+="
+	dev-vcs/git
+"
+BDEPEND="
+	>=dev-python/flit-core-3.8[${PYTHON_USEDEP}]
+	>=dev-python/snakeoil-0.10.11[${PYTHON_USEDEP}]
+	test? (
+		x11-misc/xdg-utils
+	)
+"
+
+distutils_enable_sphinx doc \
+	">=dev-python/snakeoil-0.10.11" \
+	dev-python/tomli
+EPYTEST_PLUGINS=( pkgcore )
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake PYTHON="${EPYTHON}" man
+
+	sphinx_compile_all # HTML pages only
+}
+
+python_install_all() {
+	# If USE=doc, there'll be newly generated docs which we install instead.
+	if use doc || [[ ${PV} != *9999 ]]; then
+		doman build/sphinx/man/*
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "sending email support" x11-misc/xdg-utils
+	optfeature "tatt subcommand" "app-portage/nattka dev-python/jinja2"
+}