media-plugins/audacious-plugins: Version bump to 4.4.1

Closes: https://bugs.gentoo.org/936859 Signed-off-by: Matt Turner <mattst88@gentoo.org>
2026-08-24 06:48:18 -07:00 · 2024-09-24 21:50:20 -04:00
parent 362519f49d
commit f5b060cbb5
2 changed files with 205 additions and 0 deletions
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1 +1,2 @@
 DIST audacious-plugins-4.3.1.tar.bz2 1786114 BLAKE2B 7d0a88411dc389e9f250ac126c02eff217ab4feb581527789cfe190f0fd997671fe06664d574d531296d884b2ae4f85f31a25f79ef09bd9db39640f17a0a97cf SHA512 ca065b4558406702e4f2aa2ac085ea02d3215e689e09e9c0b6a740970a469297910df52cd222997e8a4206a68d3a064ac3f6d94c6412830ce8bd34a5b42c30da
+DIST audacious-plugins-4.4.1.tar.bz2 1815238 BLAKE2B 4ffa61818eeb01a34697c576b30832c7e4719c715080fec2b0d08f09ccce2ff9a8f95b6ce7af63ca5bf68de5c320258ef62716bb6819fd76cf7406546a0bf8c7 SHA512 0c97b4c1ba635b53f416680de57b6b5921b8f0afcefa713129475c006585d53581e8f693f89e705284383ce2f3f6c3e01def8bce9ba1371a18bee7e007884389
--- a/media-plugins/audacious-plugins/audacious-plugins-4.4.1.ebuild
+++ b/media-plugins/audacious-plugins/audacious-plugins-4.4.1.ebuild
@@ -0,0 +1,204 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+SRC_URI="https://distfiles.audacious-media-player.org/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="
+	aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme gtk http jack
+	lame libnotify libsamplerate lirc mms modplug mp3 opengl openmpt opus
+	pipewire pulseaudio qt6 scrobbler sdl sid sndfile soxr speedpitch
+	streamtuner vorbis wavpack X
+"
+
+REQUIRED_USE="
+	ampache? ( http )
+	streamtuner? ( http )
+"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+DEPEND="
+	app-arch/unzip
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	~media-sound/audacious-${PV}[gtk=,qt6=]
+	sys-libs/zlib
+	>=x11-libs/gdk-pixbuf-2.26:2
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1*:= )
+	bs2b? ( >=media-libs/libbs2b-3.0.0 )
+	cdda? (
+		>=dev-libs/libcdio-0.70:=
+		dev-libs/libcdio-paranoia:=
+		>=media-libs/libcddb-1.2.1
+	)
+	cue? ( media-libs/libcue:= )
+	ffmpeg? ( >=media-video/ffmpeg-0.7.3:= )
+	flac? (
+		>=media-libs/flac-1.2.1-r1:=
+		>=media-libs/libvorbis-1.0
+	)
+	fluidsynth? ( >=media-sound/fluidsynth-1.0.6:= )
+	gtk? (
+		>=dev-libs/json-glib-1.0
+		x11-libs/cairo
+		>=x11-libs/gtk+-3.22:3
+		x11-libs/pango
+		X? (
+			opengl? ( virtual/opengl )
+			x11-libs/libX11
+			x11-libs/libXcomposite
+			x11-libs/libXrender
+		)
+	)
+	http? ( >=net-libs/neon-0.27 )
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( media-sound/mpg123-base )
+	openmpt? ( >=media-libs/libopenmpt-0.2 )
+	opus? ( >=media-libs/opusfile-0.4 )
+	pipewire? ( >=media-video/pipewire-0.3.26:= )
+	pulseaudio? ( >=media-libs/libpulse-0.9.5 )
+	qt6? (
+		dev-qt/qtbase:6[gui,opengl?,widgets]
+		dev-qt/qtmultimedia:6
+		X? (
+			dev-qt/qtbase:6=[X]
+			x11-libs/libX11
+		)
+	)
+	scrobbler? ( >=net-misc/curl-7.9.7 )
+	sdl? ( >=media-libs/libsdl2-2.0[sound] )
+	sid? ( >=media-libs/libsidplayfp-2.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	streamtuner? ( dev-qt/qtbase:6[network] )
+	vorbis? (
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.0
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+}
+
+src_prepare() {
+	default
+	if ! use X; then
+		sed -i -e "s/dependency('x11',.*)/disabler()/" meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		# GUI toolkits
+		$(meson_use gtk)
+		-Dgtk2=false
+		$(meson_use qt6 qt)
+		-Dqt5=false
+
+		# container plugins
+		$(meson_use cue cue)
+
+		# transport plugins
+		$(meson_use mms mms)
+		$(meson_use http neon)
+
+		# input plugins
+		$(meson_use aac aac)
+		-Dadplug=false
+		$(meson_use fluidsynth amidiplug)
+		$(meson_use cdda cdaudio)
+		$(meson_use gme console)
+		$(meson_use ffmpeg ffaudio)
+		$(meson_use flac flac)
+		$(meson_use modplug modplug)
+		$(meson_use mp3 mpg123)
+		$(meson_use openmpt openmpt)
+		$(meson_use opus opus)
+		$(meson_use sid sid)
+		$(meson_use sndfile sndfile)
+		$(meson_use vorbis vorbis)
+		$(meson_use wavpack wavpack)
+
+		# output plugins
+		$(meson_use alsa alsa)
+		-Dcoreaudio=false
+		# filewriter
+		$(meson_use flac filewriter-flac)
+		$(meson_use lame filewriter-mp3)
+		$(meson_use vorbis filewriter-ogg)
+		$(meson_use jack jack)
+		-Doss=false
+		$(meson_use pipewire pipewire)
+		$(meson_use pulseaudio pulse)
+		$(meson_use qt6 qtaudio)
+		$(meson_use sdl sdlout)
+		-Dsndio=false
+
+		# general plugins
+		$(meson_use ampache ampache)
+		$(meson_use X aosd)
+		$(meson_use X hotkey)
+		$(meson_use lirc lirc)
+		-Dmac-media-keys=false
+		-Dmpris2=true
+		$(meson_use libnotify notify)
+		$(meson_use scrobbler scrobbler2)
+		-Dsongchange=true
+		$(meson_use streamtuner streamtuner)
+
+		# effect plugins
+		$(meson_use bs2b bs2b)
+		$(meson_use libsamplerate resample)
+		$(meson_use soxr soxr)
+		$(meson_use speedpitch speedpitch)
+
+		# visualization plugins
+		$(meson_use opengl gl-spectrum)
+		-Dvumeter=true
+	)
+
+	meson_src_configure
+}