dev-python/alembic: Bump to 1.18.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/alembic/Manifest

@@ -1 +1,2 @@
 DIST alembic-1.18.4.tar.gz 2056725 BLAKE2B 5de761b6dc383a4f44532bcbeeb6520836cae8992a09c24a5e268d05c835caa5d5e395873c97b650942fe94b995cc995dae8f8c57278d28aa3d1c0987830e5f1 SHA512 ae38b0551858573b6b602b56537a518c7169d4fadef7b11d8112b2427402b745ea5e3cd4387c2b49fec8158cf505de7206919caa10d73445446bb53e264fd448
+DIST alembic-1.18.5.tar.gz 2060480 BLAKE2B cc85b5ebd73920c8f0afe2b9884aab1f30718b94a7ccb4b117186a9088b4141dce27dd505ce5c3015f3b93cabc837ad33e0905117ceee34fde77782b45875a6b SHA512 41d9675e2c99d339e2aa92e670acc0d562ab6a23d2006f2180478fa912ede643be959ca89713678adffe37deb20118a0d67ea7c023b2dea15d3acb5be18721fc

dev-python/alembic/alembic-1.18.5.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Database migrations tool, written by the author of SQLAlchemy"
+HOMEPAGE="
+	https://github.com/sqlalchemy/alembic/
+	https://pypi.org/project/alembic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="doc"
+
+RDEPEND="
+	>=dev-python/sqlalchemy-1.4.23[${PYTHON_USEDEP}]
+	dev-python/mako[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.12[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		sys-libs/timezone-data
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	if ! has_version "dev-python/black[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_post_write.py::RunHookTest::test_module
+			tests/test_post_write.py::RunHookTest::test_module_black_with_cwd
+			tests/test_post_write.py::RunHookTest::test_module_filename_interpolation
+			tests/test_post_write.py::RunHookTest::test_module_path_in_config
+		)
+	fi
+
+	# setup.cfg contains -p no:warnings in addopts which triggers
+	# datetime.utcfromtimestamp() deprecation warning as an error in py3.12
+	epytest -o addopts=
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/. )
+	distutils-r1_python_install_all
+}