kde-apps/umbrello: 23.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/umbrello/Manifest

@@ -1,2 +1,3 @@
 DIST umbrello-23.04.0.tar.xz 5774008 BLAKE2B 25b8ab6c63c5d5813e3348da7d7e08bbdb4b3648891d769f2a6c590935b52eee29f08014f5944fdd76080bb286ed9df1ae437f04dc9967ff0b37b584f79f9094 SHA512 aca07d2bdea918ed3d3b12cc3a8dd0bbd875200f7326e6a1d011ee04a98feefb49e23b015aa0bb089b3f1e9bc0d05029fad597ec8206020bb7f8e72bf20127fd
 DIST umbrello-23.04.2.tar.xz 5773540 BLAKE2B 0ef0266f805e21306d28a4cb22bfd7ba1cd2b79e30241656d382a5d0a8b8b30b040b62873b2e7db6bfd884ff330ca03c40059e8b914195855e8df67c5fca14b9 SHA512 d2cb16c7b818d8e4b256cfb29792e3a15dc99d426e53331d24d30c1d6b4422dd9e5a24dfdf2ccf19f1e330393be5a4f619151e8f6546b1db5f722581cee4c35d
+DIST umbrello-23.04.3.tar.xz 5773852 BLAKE2B 83633b5f6bd9a6ca34d85cd03fa41cedc5cf33aca4012a10c80f3500baf04887a6c2a9a5dce503df411e9cf88b71f4606983a5fef6f6de744c883cffe309055f SHA512 01a4c10405b813ffcb67cbefdb0fb4d3f523148ee8fd5058755d3e8a90199e94d8b781a2e88541b6d607c2b44d42dc7af73377055c06bc26bbbd9fc0a35a36fc

kde-apps/umbrello/umbrello-23.04.3.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_QTHELP="false" # TODO: figure out install error
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="KDE UML Modeller"
+HOMEPAGE="https://apps.kde.org/umbrello/ https://umbrello.kde.org"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="php"
+
+RDEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	php? (
+		dev-util/kdevelop:5=
+		dev-util/kdevelop-pg-qt:5
+		dev-util/kdevelop-php:5
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-23.03.80-gentoo-docbundledir.patch # fix hardcoded path
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON # broken, re-enable w/ ECM_QTHELP
+		-DBUILD_APIDOC=OFF
+		-DBUILD_PHP_IMPORT=$(usex php)
+		-DBUILD_unittests=$(usex test)
+	)
+	use test && mycmakeargs+=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_LLVM=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_Clang=ON
+		-DCMAKE_DISABLE_FIND_PACKAGE_CLANG=ON
+	)
+
+	ecm_src_configure
+}