dev-embedded/u-boot-tools: bump up to 2020.04-r2

Bug: https://bugs.gentoo.org/771555
Closes: https://bugs.gentoo.org/745117
Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

dev-embedded/u-boot-tools/Manifest

@@ -1 +1,2 @@
 DIST u-boot-2020.04.tar.bz2 15065656 BLAKE2B 29cf8be6027ce46e3bf3fae9b6736e6aba46dba2904112f845d79f50b52b7c7ff3437c71dac6ab22d112347467fb5baaa3ec421cb842ba3ae9b547e4f8378d03 SHA512 e04fe54883149123730605b084324ac0d1d72ce6913467bbe587a5a2675bcf7bb393405d9a446dc0c64ba42abc1e862ae5a132e9e51aa7390e2e9fce045af8d8
+DIST u-boot-2021.04-rc2.tar.bz2 16620315 BLAKE2B e16c167346ef3999443855b9a702bf28faacf51b7887c84096f7a372a0c820d6ed9f06c1dd209b4070adf8000853b58b7b9b81c5b32a973d37558acf1da2edfa SHA512 7bf07f15e0c5f5e63ef8cb9568278ea7c209e484bbb599c47b22a8d2e5c007cc204eec365e5328dea3e7b016cd6ba0cb4c917330cc76163b1016f7c7762ad1bf

dev-embedded/u-boot-tools/u-boot-tools-2021.04_rc2.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+MY_P="u-boot-${PV/_/-}"
+DESCRIPTION="utilities for working with Das U-Boot"
+HOMEPAGE="https://www.denx.de/wiki/U-Boot/WebHome"
+SRC_URI="ftp://ftp.denx.de/pub/u-boot/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="dev-libs/openssl:0="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	default
+	sed -i 's:\bpkg-config\b:${PKG_CONFIG}:g' \
+		scripts/kconfig/{g,m,n,q}conf-cfg.sh \
+		scripts/kconfig/Makefile \
+		tools/Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC PKG_CONFIG
+}
+
+src_compile() {
+	# Unset a few KBUILD variables. Bug #540476
+	unset KBUILD_OUTPUT KBUILD_SRC
+
+	emake \
+		V=1 \
+		AR="${AR}" \
+		CC="${CC}" \
+		HOSTCC="${CC}" \
+		HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
+		HOSTLDFLAGS="${LDFLAGS}" \
+		tools-only_defconfig
+
+	emake \
+		V=1 \
+		NO_SDL=1 \
+		HOSTSTRIP=: \
+		STRIP=: \
+		AR="${AR}" \
+		CC="${CC}" \
+		HOSTCC="${CC}" \
+		HOSTCFLAGS="${CFLAGS} ${CPPFLAGS}"' $(HOSTCPPFLAGS)' \
+		HOSTLDFLAGS="${LDFLAGS}" \
+		CONFIG_ENV_OVERWRITE=y \
+		tools-all
+}
+
+src_test() { :; }
+
+src_install() {
+	cd tools || die
+	dobin bmp_logo dumpimage fdtgrep gen_eth_addr img2srec mkenvimage mkimage
+	dobin env/fw_printenv
+	dosym fw_printenv /usr/bin/fw_setenv
+	insinto /etc
+	doins env/fw_env.config
+	doman "${S}"/doc/mkimage.1
+}