mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
app-emacs/org-mode: bump to 9.8.1
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST org-mode-9.8.1.tar.xz 1779608 BLAKE2B d4d9bed5d58323b8e6e4a247d54c3158506eda8778458a1ec81425dca7cf915e5178a124993a20fd1266523069dc3e16efce8c32182d093b1137a665255062c3 SHA512 4b1353c9dd9cd06c3a1dd7b275061063eb25d37daaf6885099fdba5ad655925ddc4a14c3183200648e3c96c5f3d533ea79aac5380849b07a9f332442bef59732
|
||||
DIST org-mode-9.8.tar.xz 1779204 BLAKE2B e615eb1e2ab9b32fa371db7ec50832d5121282d4efeac5254cc49b5b2bbf984717f46c0ed5e21e3eea72f63a2f3e259c99ccf498ff6047f09771387b22894c64 SHA512 b922b5a70a4a905125312fb26993231dd8ee24da216714755f98ed3ebb2b1a90b538e8a0db9e90834372d240970672687927b210f1e3bf5d107302aa55f1efc8
|
||||
|
||||
@@ -0,0 +1,87 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
NEED_EMACS="28"
|
||||
|
||||
inherit elisp readme.gentoo-r1
|
||||
|
||||
DESCRIPTION="An Emacs mode for notes and project planning"
|
||||
HOMEPAGE="https://orgmode.org/"
|
||||
|
||||
if [[ "${PV}" == 9999 ]] ; then
|
||||
inherit git-r3
|
||||
|
||||
EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}"
|
||||
EGIT_CHECKOUT_DIR="${WORKDIR}/org"
|
||||
S="${WORKDIR}/org"
|
||||
else
|
||||
# git archive --prefix=${P}/ release_${PV} | xz > ${P}.tar.xz
|
||||
SRC_URI="https://dev.gentoo.org/~xgqt/distfiles/repackaged/${P}.tar.xz"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~riscv ~x86"
|
||||
fi
|
||||
|
||||
LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
|
||||
SLOT="0"
|
||||
IUSE="doc odt-schema"
|
||||
|
||||
BDEPEND="
|
||||
doc? (
|
||||
virtual/texi2dvi
|
||||
)
|
||||
"
|
||||
|
||||
DOCS=( README.org CONTRIBUTE.org etc/ORG-NEWS )
|
||||
SITEFILE="50${PN}-gentoo.el"
|
||||
|
||||
src_prepare() {
|
||||
elisp_src_prepare
|
||||
|
||||
# Remove failing tests.
|
||||
rm testing/lisp/test-{ob{,-exp,-tangle,-shell},org-clock,ox-icalendar}.el \
|
||||
|| die "failed to remove some test files"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
elisp_src_configure
|
||||
|
||||
if use doc ; then
|
||||
DOCS+=( doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf )
|
||||
fi
|
||||
|
||||
EMAKEARGS=(
|
||||
ORGVERSION="${PV}"
|
||||
ETCDIRS="styles csl $(usev odt-schema schema)"
|
||||
lispdir="${EPREFIX}${SITELISP}/${PN}"
|
||||
datadir="${EPREFIX}${SITEETC}/${PN}"
|
||||
infodir="${EPREFIX}/usr/share/info"
|
||||
)
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake -j1 "${EMAKEARGS[@]}"
|
||||
|
||||
if use doc ; then
|
||||
emake -j1 pdf
|
||||
emake -j1 card
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
local -x LANG="C"
|
||||
|
||||
emake -j1 "${EMAKEARGS[@]}" TEST_NO_AUTOCLEAN="TRUE" test-dirty
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake -j1 "${EMAKEARGS[@]}" DESTDIR="${D}" install
|
||||
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
|
||||
einstalldocs
|
||||
|
||||
local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
|
||||
so you may have to install one or more additional packages.
|
||||
A non-exhaustive list of these dependencies may be found at
|
||||
<http://orgmode.org/worg/org-dependencies.html>."
|
||||
readme.gentoo_create_doc
|
||||
}
|
||||
Reference in New Issue
Block a user