mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-07-30 22:48:07 -07:00
dev-java/oracle-jre-bin: Security bump to 1.8.0.181
Bug: https://bugs.gentoo.org/661456 Package-Manager: Portage-2.3.45, Repoman-2.3.10
This commit is contained in:
James Le Cuirot
@@ -1,5 +1,7 @@
|
||||
DIST jre-8u172-linux-i586.tar.gz 84306480 BLAKE2B c5763bf5631a5ac246e5bbb6eaec98bac59ece15a9779c2861b474584bc86caafa333575d03fe875c3fcd3c47cbb506b905c274bf2b621f810846411b7619d5d SHA512 a4773fe39b69f22e6a646cd6b8ebdf189252e5b686f4000e43fc418ef133ac1b3e24374693c41eed5b3063849f33bbbf70a3ffe04c52ef9b1b8ac1b8d1d0dd22
|
||||
DIST jre-8u172-linux-x64.tar.gz 81182269 BLAKE2B f9c7afc534cc9e8c60458a58a768692ee95cb9401c238974daeb4ada5aa26b45f7a0de2b1785de77fb85ceaefc717b49cf08238f31032437bb620343cd468c30 SHA512 e113138946eb95fb2c9ea8bdc5ca4b8d0c3e9ae35baaf12a04c0f5a0c9af390f181d2e39fa1c71eb8c91d734a944c9239fdc10dcfc9b8a19829dad24dd35447f
|
||||
DIST jre-8u181-linux-i586.tar.gz 84309787 BLAKE2B 3aa9f47698a35ca91bbc61d2f3ec43f5ee626b74fb913eb11be8e1478d8aad780b5ea672de4dcb6bd6c598058786d26d491d01a45d5f3cb5044d1f48db26c7d6 SHA512 86e4532248e383f6bca875bf039f4f852b79260b4d5affbbd5deb9cf2ea3e585ced9f1fe054526529dcc3dfbe031a829df078a7591dbc3cf3da7913703de7231
|
||||
DIST jre-8u181-linux-x64.tar.gz 81191893 BLAKE2B c29d638b7dae9cc58d9de6e43f1af397cab04786045e4956d05cd8c3825af1f27e8a77b42a9d4b9d8ab7d15aa5b94349fd8c98ca37fadb271dc0bd868d513491 SHA512 dea7bc79210d23ddc58a7013bea8386169b9ab6c156995a2190dac298919c933641639173cf3426730b248004767449c5a62057d6736f897831d8c86b36c5bed
|
||||
DIST jre-9.0.4_linux-x64_bin.tar.gz 87045353 BLAKE2B ccf3c0d725ca1431261a0b38cc06851fc10651415982fa2d97f512972c088c2c158ee51710b59e04f89326dd4cbb4c1ef8ecf514af190fbdc2be07cd222fd5d8 SHA512 20310fe68c89d26a89523eb1fe583eb5706fe2458342f5be0dfb4badd1d9df6ba25b00463f080fceb7c22781ff1555a61b29d187d8b02e1f9e165120b8140c3b
|
||||
DIST jre-9.0.4_osx-x64_bin.tar.gz 74599903 BLAKE2B a1bd4d51ee645347fcb735e46ee3311d34933bb0dbb20b9a668ed7b817be1d0432f4152f53f57a9fc16d6b6b7f38ea4118f5cae86a8b71143db0091c9baf62de SHA512 fc4bc4a062313a7e33943ace27287ba6e551727f0cf81d9a18f9f8c2f57b0ae00bd0d8619a65f596d75d4869fea757fedae3efdd8ba3ced58fa28b7cf93b3a85
|
||||
DIST jre-9.0.4_solaris-sparcv9_bin.tar.gz 54879298 BLAKE2B fb3ce1eefdb12378b28f5af0f0bbc1d9f3252eee5646be237b2ddc0ead37ed253fb73900475777c3f67d39b47112e0c2db2a18f6a05da7c5c19cd965e5513827 SHA512 709219f51d7455c127a38953babad39b344dee1275ad0fe65a0116e8fb15a10482589ba881ccae7910acff8f00aa7856c726c03daa8f3947d742bbbc09a276dd
|
||||
|
||||
220
dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.181.ebuild
Normal file
220
dev-java/oracle-jre-bin/oracle-jre-bin-1.8.0.181.ebuild
Normal file
@@ -0,0 +1,220 @@
|
||||
# Copyright 1999-2018 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
|
||||
inherit desktop gnome2-utils java-vm-2 prefix versionator
|
||||
|
||||
KEYWORDS="-* ~amd64 ~x86"
|
||||
|
||||
if [[ "$(get_version_component_range 4)" == 0 ]] ; then
|
||||
S_PV="$(get_version_component_range 1-3)"
|
||||
else
|
||||
MY_PV_EXT="u$(get_version_component_range 4)"
|
||||
S_PV="$(get_version_component_range 1-4)"
|
||||
fi
|
||||
|
||||
MY_PV="$(get_version_component_range 2)${MY_PV_EXT}"
|
||||
|
||||
declare -A ARCH_FILES
|
||||
ARCH_FILES[amd64]="jre-${MY_PV}-linux-x64.tar.gz"
|
||||
ARCH_FILES[x86]="jre-${MY_PV}-linux-i586.tar.gz"
|
||||
|
||||
for keyword in ${KEYWORDS//-\*} ; do
|
||||
SRC_URI+=" ${keyword#\~}? ( ${ARCH_FILES[${keyword#\~}]} )"
|
||||
done
|
||||
|
||||
DESCRIPTION="Oracle's Java SE Runtime Environment"
|
||||
HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
|
||||
LICENSE="Oracle-BCLA-JavaSE"
|
||||
SLOT="1.8"
|
||||
IUSE="alsa commercial cups +fontconfig headless-awt javafx jce nsplugin selinux"
|
||||
RESTRICT="fetch preserve-libs strip"
|
||||
QA_PREBUILT="*"
|
||||
|
||||
# NOTES:
|
||||
#
|
||||
# * cups is dlopened.
|
||||
#
|
||||
# * libpng is also dlopened but only by libsplashscreen, which isn't
|
||||
# important, so we can exclude that.
|
||||
#
|
||||
# * We still need to work out the exact AWT and JavaFX dependencies
|
||||
# under MacOS. It doesn't appear to use many, if any, of the
|
||||
# dependencies below.
|
||||
#
|
||||
RDEPEND="!x64-macos? (
|
||||
!headless-awt? (
|
||||
x11-libs/libX11
|
||||
x11-libs/libXext
|
||||
x11-libs/libXi
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXtst
|
||||
)
|
||||
javafx? (
|
||||
dev-libs/glib:2
|
||||
dev-libs/libxml2:2
|
||||
dev-libs/libxslt
|
||||
media-libs/freetype:2
|
||||
x11-libs/cairo
|
||||
x11-libs/gtk+:2
|
||||
x11-libs/libX11
|
||||
x11-libs/libXtst
|
||||
x11-libs/libXxf86vm
|
||||
x11-libs/pango
|
||||
virtual/opengl
|
||||
)
|
||||
)
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
cups? ( net-print/cups )
|
||||
fontconfig? ( media-libs/fontconfig:1.0 )
|
||||
!prefix? ( sys-libs/glibc:* )
|
||||
selinux? ( sec-policy/selinux-java )"
|
||||
|
||||
DEPEND="app-arch/zip"
|
||||
|
||||
S="${WORKDIR}/jre$(replace_version_separator 3 _ ${S_PV})"
|
||||
|
||||
pkg_nofetch() {
|
||||
einfo "Please download ${ARCH_FILES[${ARCH}]} and move it to"
|
||||
einfo "your distfiles directory:"
|
||||
einfo
|
||||
einfo " http://www.oracle.com/technetwork/java/javase/downloads/jre8-downloads-2133155.html"
|
||||
einfo
|
||||
einfo "If the above mentioned URL does not point to the correct version anymore,"
|
||||
einfo "please download the file from Oracle's Java download archive:"
|
||||
einfo
|
||||
einfo " http://www.oracle.com/technetwork/java/javase/downloads/java-archive-javase8-2177648.html"
|
||||
einfo
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# Remove the hook that calls Oracle's evil usage tracker. Not just
|
||||
# because it's evil but because it breaks the sandbox during builds
|
||||
# and we can't find any other feasible way to disable it or make it
|
||||
# write somewhere else. See bug #559936 for details.
|
||||
zip -d lib/rt.jar sun/misc/PostVMInitHook.class || die
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local dest="/opt/${P}"
|
||||
local ddest="${ED}${dest#/}"
|
||||
|
||||
# Create files used as storage for system preferences.
|
||||
mkdir .systemPrefs || die
|
||||
touch .systemPrefs/.system.lock || die
|
||||
touch .systemPrefs/.systemRootModFile || die
|
||||
|
||||
if ! use alsa ; then
|
||||
rm -vf lib/*/libjsoundalsa.* || die
|
||||
fi
|
||||
|
||||
if ! use commercial ; then
|
||||
rm -vfr lib/jfr* || die
|
||||
fi
|
||||
|
||||
if use headless-awt ; then
|
||||
rm -vf lib/*/lib*{[jx]awt,splashscreen}* \
|
||||
bin/{javaws,policytool} || die
|
||||
fi
|
||||
|
||||
if ! use javafx ; then
|
||||
rm -vf lib/*/lib*{decora,fx,glass,prism}* \
|
||||
lib/*/libgstreamer-lite.* lib/{,ext/}*fx* || die
|
||||
fi
|
||||
|
||||
if ! use nsplugin ; then
|
||||
rm -vf lib/*/libnpjp2.* || die
|
||||
else
|
||||
local nsplugin=$(echo lib/*/libnpjp2.*)
|
||||
local nsplugin_link=${nsplugin##*/}
|
||||
nsplugin_link=${nsplugin_link/./-${PN}-${SLOT}.}
|
||||
dosym "${dest}/${nsplugin}" "/usr/$(get_libdir)/nsbrowser/plugins/${nsplugin_link}"
|
||||
fi
|
||||
|
||||
# Even though plugins linked against multiple ffmpeg versions are
|
||||
# provided, they generally lag behind what Gentoo has available.
|
||||
rm -vf lib/*/libavplugin* || die
|
||||
|
||||
# Prune all fontconfig files so that libfontconfig will be used.
|
||||
rm -v lib/fontconfig.* || die
|
||||
|
||||
# Install desktop file for the Java Control Panel. Using
|
||||
# ${PN}-${SLOT} to prevent file collision with JDK and other slots.
|
||||
if [[ -d lib/desktop/icons ]] ; then
|
||||
local icon
|
||||
pushd lib/desktop/icons >/dev/null || die
|
||||
for icon in */*/apps/sun-jcontrol.png ; do
|
||||
insinto /usr/share/icons/"${icon%/*}"
|
||||
newins "${icon}" sun-jcontrol-${PN}-${SLOT}.png
|
||||
done
|
||||
popd >/dev/null || die
|
||||
make_desktop_entry \
|
||||
"${dest}"/bin/jcontrol \
|
||||
"Java Control Panel for Oracle JRE ${SLOT}" \
|
||||
sun-jcontrol-${PN}-${SLOT} \
|
||||
"Settings;Java;"
|
||||
fi
|
||||
|
||||
dodoc COPYRIGHT
|
||||
dodir "${dest}"
|
||||
cp -pPR bin lib man "${ddest}" || die
|
||||
|
||||
ln -s policy/$(usex jce unlimited limited)/{US_export,local}_policy.jar \
|
||||
"${ddest}"/lib/security/ || die
|
||||
|
||||
# Only install Gentoo-specific fontconfig if flag is disabled.
|
||||
# https://docs.oracle.com/javase/8/docs/technotes/guides/intl/fontconfig.html
|
||||
if ! use fontconfig ; then
|
||||
insinto "${dest}"/lib/
|
||||
doins "$(prefixify_ro "${FILESDIR}"/fontconfig.properties)"
|
||||
fi
|
||||
|
||||
# Needs to be done before CDS, bug #215225.
|
||||
java-vm_set-pax-markings "${ddest}"
|
||||
|
||||
# See bug #207282.
|
||||
einfo "Creating the Class Data Sharing archives"
|
||||
case ${ARCH} in
|
||||
arm|ia64)
|
||||
${ddest}/bin/java -client -Xshare:dump || die
|
||||
;;
|
||||
x86)
|
||||
${ddest}/bin/java -client -Xshare:dump || die
|
||||
# limit heap size for large memory on x86 #467518
|
||||
# this is a workaround and shouldn't be needed.
|
||||
${ddest}/bin/java -server -Xms64m -Xmx64m -Xshare:dump || die
|
||||
;;
|
||||
*)
|
||||
${ddest}/bin/java -server -Xshare:dump || die
|
||||
;;
|
||||
esac
|
||||
|
||||
# Remove empty dirs we might have copied.
|
||||
find "${D}" -type d -empty -exec rmdir -v {} + || die
|
||||
|
||||
java-vm_install-env "${FILESDIR}"/${PN}.env.sh
|
||||
java-vm_revdep-mask
|
||||
java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
gnome2_icon_savelist
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
gnome2_icon_cache_update
|
||||
java-vm-2_pkg_postinst
|
||||
|
||||
if ! use headless-awt && ! use javafx ; then
|
||||
ewarn "You have disabled the javafx flag. Some modern desktop Java applications"
|
||||
ewarn "require this and they may fail with a confusing error message."
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
gnome2_icon_cache_update
|
||||
java-vm-2_pkg_postrm
|
||||
}
|
||||
Reference in New Issue
Block a user