net-libs/libssh: drop 0.10.4

Bug: https://bugs.gentoo.org/905746 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-09-24 17:09:10 -07:00 · 2023-05-13 18:25:03 +02:00
parent 37bf0bcab2
commit f3e5dca640
2 changed files with 0 additions and 136 deletions
--- a/net-libs/libssh/Manifest
+++ b/net-libs/libssh/Manifest
@@ -1,2 +1 @@
-DIST libssh-0.10.4.tar.xz 554920 BLAKE2B 9349a688bdbd7c0d3bc93d6d0d6d55122ae9f918b922baeae8a7c6d4ae3ec340e6607afdd8a47055176f31531aefa94b6cc2bda25d59625fe1a7f83823dd75f9 SHA512 01ee52d480201d9886c15e81137c185334b404d1c8e8b743ddf58e95fe8619c8c013616a49807bd1111fde72fa177cd35f3c22b66cbf5d720b5abfacdf7601ed
 DIST libssh-0.10.5.tar.xz 557776 BLAKE2B de147f25fa9116743b5b2d08548c2b28b31d7b76b10e249b0a52fa19dfa09762d37ad5a5d1eaf7db89d8713144b8d3608aa2b48ce29ed324e4154493a9fcebfe SHA512 2b758f9df2b5937865d4aee775ffeafafe3ae6739a89dfc470e38c7394e3c3cb5fcf8f842fdae04929890ee7e47bf8f50e3a38e82dfd26a009f3aae009d589e0
--- a/net-libs/libssh/libssh-0.10.4.ebuild
+++ b/net-libs/libssh/libssh-0.10.4.ebuild
@@ -1,135 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake-multilib
-
-DESCRIPTION="Access a working SSH implementation by means of a library"
-HOMEPAGE="https://www.libssh.org/"
-
-if [[ ${PV} == *9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.libssh.org/projects/libssh.git"
-else
-	SRC_URI="https://www.libssh.org/files/$(ver_cut 1-2)/${P}.tar.xz"
-	KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
-fi
-
-LICENSE="LGPL-2.1"
-SLOT="0/4" # subslot = soname major version
-IUSE="debug doc examples gcrypt gssapi mbedtls pcap server +sftp static-libs test zlib"
-# Maintainer: check IUSE-defaults at DefineOptions.cmake
-
-REQUIRED_USE="?? ( gcrypt mbedtls )"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	!gcrypt? (
-		!mbedtls? (
-			>=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}]
-		)
-	)
-	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
-	gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
-	mbedtls? ( net-libs/mbedtls:=[${MULTILIB_USEDEP}] )
-	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
-"
-DEPEND="${RDEPEND}
-	test? (
-		>=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}]
-		elibc_musl? ( sys-libs/argp-standalone )
-	)
-"
-BDEPEND="doc? ( app-doc/doxygen[dot] )"
-
-DOCS=( AUTHORS CHANGELOG README )
-
-src_prepare() {
-	cmake_src_prepare
-
-	# just install the examples, do not compile them
-	cmake_comment_add_subdirectory examples
-
-	sed -e "/^check_include_file.*HAVE_VALGRIND_VALGRIND_H/s/^/#DONT /" \
-		-i ConfigureChecks.cmake || die
-
-	if use test; then
-		local skip_tests=(
-			# keyfile torture test is currently broken
-			-e "/torture_keyfiles/d"
-
-			# Tries to expand ~ which fails w/ portage homedir
-			# (torture_path_expand_tilde_unix and torture_config_make_absolute_no_sshdir)
-			-e "/torture_misc/d"
-			-e "/torture_config/d"
-		)
-
-		# Disable tests that take too long (bug #677006)
-		if use sparc; then
-			skip_tests+=(
-				-e "/torture_threads_pki_rsa/d"
-				-e "/torture_pki_dsa/d"
-			)
-		fi
-
-		if (( ${#skip_tests[@]} )) ; then
-			sed -i "${skip_tests[@]}" tests/unittests/CMakeLists.txt || die
-		fi
-
-		if use elibc_musl; then
-			sed -e "/SOLARIS/d" \
-				-i tests/CMakeLists.txt || die
-		fi
-	fi
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DWITH_NACL=OFF
-		-DWITH_STACK_PROTECTOR=OFF
-		-DWITH_STACK_PROTECTOR_STRONG=OFF
-		-DWITH_DEBUG_CALLTRACE=$(usex debug)
-		-DWITH_DEBUG_CRYPTO=$(usex debug)
-		-DWITH_GCRYPT=$(usex gcrypt)
-		-DWITH_GSSAPI=$(usex gssapi)
-		-DWITH_MBEDTLS=$(usex mbedtls)
-		-DWITH_PCAP=$(usex pcap)
-		-DWITH_SERVER=$(usex server)
-		-DWITH_SFTP=$(usex sftp)
-		-DBUILD_STATIC_LIB=$(usex static-libs)
-		# TODO: try enabling {CLIENT,SERVER}_TESTING
-		-DUNIT_TESTING=$(usex test)
-		-DWITH_ZLIB=$(usex zlib)
-	)
-
-	multilib_is_native_abi || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON )
-
-	cmake_src_configure
-}
-
-multilib_src_compile() {
-	cmake_src_compile
-	multilib_is_native_abi && use doc && cmake_src_compile docs
-}
-
-multilib_src_install() {
-	cmake_src_install
-	multilib_is_native_abi && use doc && local HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
-
-	use static-libs && dolib.a src/libssh.a
-
-	# compatibility symlink until all consumers have been updated
-	# to no longer use libssh_threads.so
-	dosym libssh.so /usr/$(get_libdir)/libssh_threads.so
-}
-
-multilib_src_install_all() {
-	use mbedtls && DOCS+=( README.mbedtls )
-	einstalldocs
-
-	if use examples; then
-		docinto examples
-		dodoc examples/*.{c,h,cpp}
-	fi
-}