dev-cpp/fbthrift: new package, add 2024.11.04.00

Signed-off-by: sin-ack <sin-ack@protonmail.com>
Signed-off-by: Sam James <sam@gentoo.org>

dev-cpp/fbthrift/Manifest

@@ -0,0 +1 @@
+DIST fbthrift-2024.11.04.00.gh.tar.gz 15541383 BLAKE2B 447fdeba8b9f270e77066d7cf8dedd64ff0e74baf58b8848b0225e936c5d0815cae764f0b38c26c4ce17d9b0f2c0ba46df3a03b2512065b7bd5d685ac7dc99d6 SHA512 b2175eac20ef9b4f15b5d9002583db7339549f660d03a1ced34289009cd99a4308a9ce340b9a37b9771a32340e80b7877b7c5498619241819cf0664e1e395bf7

dev-cpp/fbthrift/fbthrift-2024.11.04.00.ebuild

@@ -0,0 +1,57 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# dev-cpp/edencommon
+# dev-cpp/fb303
+# dev-cpp/fbthrift
+# dev-cpp/fizz
+# dev-cpp/folly
+# dev-cpp/mvfst
+# dev-cpp/wangle
+# dev-util/watchman
+
+inherit cmake
+
+DESCRIPTION="Facebook's branch of Apache Thrift (C++ bindings)"
+HOMEPAGE="https://github.com/facebook/fbthrift"
+SRC_URI="https://github.com/facebook/fbthrift/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="test"
+
+# See https://github.com/facebook/fbthrift/issues/628
+RESTRICT="test"
+
+DEPEND="
+	app-arch/zstd:=
+	~dev-cpp/fizz-${PV}:=
+	~dev-cpp/folly-${PV}:=
+	dev-cpp/gflags:=
+	dev-cpp/glog:=[gflags]
+	~dev-cpp/mvfst-${PV}:=
+	~dev-cpp/wangle-${PV}:=
+	dev-libs/boost:=[nls(+)]
+	dev-libs/libevent:=
+	dev-libs/openssl:=
+	dev-libs/xxhash:=
+	sys-libs/zlib:=
+"
+RDEPEND="
+	${DEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+		-Denable_tests=$(usex test 'ON' 'OFF')
+		-Wno-dev
+	)
+	cmake_src_configure
+}

dev-cpp/fbthrift/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>sin-ack@protonmail.com</email>
+		<name>sin-ack</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">facebook/fbthrift</remote-id>
+	</upstream>
+</pkgmetadata>