net-libs/signond: 8.61 version bump, EAPI-8 bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-libs/signond/Manifest

@@ -1 +1,2 @@
 DIST signond-8.60.tar.gz 281359 BLAKE2B 3ecd8048d8c5551c3611e48091c35a9f0fe4c972e6b4730fe1f610b4870fe86911dee04c331847deee2a50f4a04acd5a8a0d1c605d1f4f0a24272d44c289a6d3 SHA512 fb3ccc99c692506ca29d5bae39bc375ff97057734fac1551ea39105d5f8e78f3df23e01a286f73be3a606c54b40f957c3c0d985484926e57f354218e4137ff3c
+DIST signond-8.61.tar.gz 282965 BLAKE2B 8ab8f4ac3f8416ef9c1b8d8c73057ffcf0024a7e3cf6c2fa97a3119826f6c655b215e2530137c199e60e9e9518b0858fa1a23a3f107c71751f33d2a34898a610 SHA512 1652ee8e97d6aee036075f5416909649c5848e33c3c71f367176f3e5d6f9c360fd7a46c65ba877d58b3ae8fb8df0712938c5e073409ba945d66d8afeacfd6f72

net-libs/signond/signond-8.61.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils
+
+DESCRIPTION="Signon daemon for libaccounts-glib"
+HOMEPAGE="https://gitlab.com/accounts-sso"
+SRC_URI="https://gitlab.com/accounts-sso/${PN}/-/archive/VERSION_${PV}/${PN}-VERSION_${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-VERSION_${PV}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+# tests are brittle; they all pass when stars align, bug 727666
+RESTRICT="test !test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	net-libs/libproxy
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-8.60-buildsystem.patch"
+	"${FILESDIR}/${PN}-8.60-consistent-paths.patch" # bug 701142
+	"${FILESDIR}/${PN}-8.60-unused-dep.patch" # bug 727346
+)
+
+src_prepare() {
+	default
+
+	# install docs to correct location
+	sed -e "s|share/doc/\$\${PROJECT_NAME}|share/doc/${PF}|" \
+		-i doc/doc.pri || die
+	sed -e "/^documentation.path = /c\documentation.path = \$\${INSTALL_PREFIX}/share/doc/${PF}/\$\${TARGET}/" \
+		-i lib/plugins/doc/doc.pri || die
+	sed -e "/^documentation.path = /c\documentation.path = \$\${INSTALL_PREFIX}/share/doc/${PF}/libsignon-qt/" \
+		-i lib/SignOn/doc/doc.pri || die
+
+	use doc || sed -e "/include(\s*doc\/doc.pri\s*)/d" \
+		-i signon.pro lib/SignOn/SignOn.pro lib/plugins/plugins.pro || die
+
+	use test || sed -e '/^SUBDIRS/s/tests//' \
+		-i signon.pro || die "couldn't disable tests"
+}
+
+src_configure() {
+	eqmake5 PREFIX="${EPREFIX}"/usr LIBDIR=$(get_libdir)
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+}