app-misc/golly: bump to 5.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-misc/golly/Manifest

@@ -1 +1,2 @@
 DIST golly-4.3-src.tar.gz 15488205 BLAKE2B 0789bc3e50f43083633f699c5e4ff20fd314cfa776d22463dce3169095e57daeadda4d9671f1b566d6786771caf029f98e4593b250cf29a73abff0c200e2f32b SHA512 daf3a0ef8b7d3f97df2c3a05a245c93eb124ebab4e7a7c0d267e22b4b7271a11cecced20b53fa88dfde145ce11450aac98e0e774f8b6419b3084952938e5a854
+DIST golly-5.0-src.tar.gz 17940916 BLAKE2B dc25dbdb9e80a24433cc8b953c7c717d6aaf47083a2557511852772c81550688a2811a8b1ce0118da669f7b89834539bc4560e2febb12c4a8739c907ee85b122 SHA512 94f77266d7d1bfc78f05f2a9a828ba136013fc1698212ccfdd233c47a77218b653c910d1f8d2c505d578fc15aa4057b13edd5fc724cade3b9f5d5aef090ab069

app-misc/golly/golly-5.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+WX_GTK_VER="3.2-gtk3"
+
+inherit desktop python-single-r1 toolchain-funcs wxwidgets xdg
+
+DESCRIPTION="Simulator for Conway's Game of Life and other cellular automata"
+HOMEPAGE="http://golly.sourceforge.net/
+	https://sourceforge.net/projects/golly/"
+
+SRC_URI="https://downloads.sourceforge.net/${PN}/${P}-src.tar.gz"
+S="${WORKDIR}/${P}-src"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/wxGTK:${WX_GTK_VER}=[X,curl,opengl,sdl,tiff]
+	${PYTHON_DEPS}
+"
+DEPEND="
+	${RDEPEND}
+"
+
+PATCHES=( "${FILESDIR}/${PN}-4.0-CFLAGS.patch" )
+
+src_configure() {
+	setup-wxwidgets
+}
+
+src_compile() {
+	local -a emakeopts=(
+		ENABLE_SOUND="yes"
+
+		GOLLYDIR="${EPREFIX}/usr/share/${PN}"
+		PYTHON="${EPYTHON}"
+		WX_CONFIG="${WX_CONFIG}"
+
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		CXX="$(tc-getCXX)"
+		CXXC="$(tc-getCXX)"
+		RANLIB="$(tc-getRANLIB)"
+	)
+	emake -C gui-wx -f makefile-gtk "${emakeopts[@]}"
+}
+
+src_install() {
+	# Has no 'make install', let's install files manually.
+	dobin golly bgolly
+
+	insinto "/usr/share/${PN}"
+	doins -r Help Patterns Scripts Rules docs
+
+	newicon --size 32 gui-wx/icons/appicon.xpm "${PN}.xpm"
+
+	# WARNING: Does not run on wayland, we have to add "GDK_BACKEND" var.
+	#  > This program wasn't compiled with EGL support required under Wayland
+	make_desktop_entry "env GDK_BACKEND=x11 ${PN}" "Golly" "${PN}" "Science"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}