kde-apps/dolphin-plugins-subversion: 23.04.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2023-04-22 11:12:31 +02:00
parent d317dc8ad3
commit f2ebdbd78b
2 changed files with 64 additions and 0 deletions
@@ -1 +1,2 @@
DIST dolphin-plugins-22.12.3.tar.xz 272276 BLAKE2B 485ac53e070a710dbfb07aa26c915f4c2b32d5f6e67e91c3d07d9740be2c50ba4fae3c8662216423ce7e63042b663e8a59dfbfe1b490d31a2cc5445d9c3ac33c SHA512 0225fc50f88e7bd28eda74ae2bfa0c36878b9fe6b9fade6ef86a26e380cd78c8c2d1d1608796e8369f6ad545876d5d533ccfbf34b02b2be07ab8abc4bb734f7a
DIST dolphin-plugins-23.04.0.tar.xz 272516 BLAKE2B b424fc4c1cac1c7109b4ea05d97bc44e348d94d36ea5e7acb06dd171f4eee1c7278b19b004ea175b3e7d567f440a9c4b362726ae051dce061073f59e6cf280f7 SHA512 0ffdeeb9296763ef23d567ddf9929b3c3ac25cebd9d8d409f5afd5cd7765d49845a7806fb718ccee31e778d517c6eb9758fbdb15014a72d1e56083c8dd145d1d
@@ -0,0 +1,63 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="false"
KDE_ORG_NAME="dolphin-plugins"
MY_PLUGIN_NAME="svn"
PVCUT=$(ver_cut 1-3)
KFMIN=5.104.0
QTMIN=5.15.5
inherit ecm gear.kde.org
DESCRIPTION="Dolphin plugin for Subversion integration"
HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="5"
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
IUSE=""
DEPEND="
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-apps/dolphin-${PVCUT}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
"
RDEPEND="${DEPEND}
dev-vcs/subversion
>=kde-apps/kompare-${PVCUT}:5
"
src_prepare() {
ecm_src_prepare
# solid, qtdbus only required by mountiso
ecm_punt_qt_module DBus
ecm_punt_kf_module Solid
# kxmlgui, qtnetwork only required by dropbox
ecm_punt_qt_module Network
ecm_punt_kf_module XmlGui
# delete non-${PN} translations
find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
}
src_configure() {
local mycmakeargs=(
-DBUILD_${MY_PLUGIN_NAME}=ON
-DBUILD_bazaar=OFF
-DBUILD_dropbox=OFF
-DBUILD_git=OFF
-DBUILD_hg=OFF
-DBUILD_mountiso=OFF
)
ecm_src_configure
}
src_install() {
ecm_src_install
rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
}