media-libs/gexiv2: bump to 0.12.0

Closes: https://bugs.gentoo.org/691774
Package-Manager: Portage-2.3.71, Repoman-2.3.17
Signed-off-by: Bernardo Meurer <bernardo@standard.ai>
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Bernardo Meurer
2019-09-28 10:13:03 +02:00
committed by Michał Górny
parent 9523f3ab85
commit f290dd88cc
3 changed files with 81 additions and 8 deletions
+1
View File
@@ -1 +1,2 @@
DIST gexiv2-0.10.10.tar.xz 638168 BLAKE2B ae75a06007dcaca4c22e463661073d796b77921a313a5bb450c488ee963f72c6095d7abc12dedc0d089a28905cf386062221073100ba3513d9fb13eb524365ee SHA512 41e5b4a9d81882ea4b1bc6f3b9ced95ca4d03f836de30ff90b7a43311e5319f7c0f46cbad767bf2b00926c8e5fd2c1e8ca2a2113c308e23b7a4c21205399abf7
DIST gexiv2-0.12.0.tar.xz 370816 BLAKE2B 7768cffafedf41948ca6ddd22614f0eb3b44a317a23ade3c8d39d5ec5ff77c0d8c61dd8dcca5108b3403e0e3ec8be6659c16445de27163e8689c6c40f5313566 SHA512 c89e7d307359c718dff1f3991acb4ece66bce985a3d8bee1c8fccf4ce39187af62684c87eaae9b0425a6fdbf147b7330902041d9588e52a4bad1da4255d245e9
+73
View File
@@ -0,0 +1,73 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
inherit meson python-r1 vala
DESCRIPTION="GObject-based wrapper around the Exiv2 library"
HOMEPAGE="https://wiki.gnome.org/Projects/gexiv2"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://gitlab.gnome.org/GNOME/gexiv2.git"
inherit git-r3
else
SRC_URI="mirror://gnome/sources/${PN}/$(ver_cut 1-2)/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
fi
LICENSE="LGPL-2.1+ GPL-2"
SLOT="0"
IUSE="gtk-doc +introspection python static-libs test +vala"
REQUIRED_USE="
python? ( introspection ${PYTHON_REQUIRED_USE} )
test? ( python introspection )
vala? ( introspection )
"
BDEPEND="
dev-util/glib-utils
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc )
test? (
dev-python/pygobject:3
media-gfx/exiv2[xmp]
)
vala? ( $(vala_depend) )
"
RDEPEND="${PYTHON_DEPS}
>=dev-libs/glib-2.38.0:2
>=media-gfx/exiv2-0.21:=
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}"
src_prepare() {
default
use vala && vala_src_prepare
}
src_configure() {
local emesonargs=(
$(meson_use introspection)
$(meson_use vala vapi)
$(meson_use gtk-doc gtk_doc)
# Prevents installation of python modules (uses install_data from meson
# which does not optimize the modules)
-Dpython2_girdir=no
-Dpython3_girdir=no
)
meson_src_configure
}
src_install() {
meson_src_install
if use python ; then
python_moduleinto gi/overrides/
python_foreach_impl python_domodule GExiv2.py
fi
}
+7 -8
View File
@@ -3,9 +3,9 @@
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{5,6} )
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
inherit meson python-r1 vala xdg-utils
inherit meson python-r1 vala
DESCRIPTION="GObject-based wrapper around the Exiv2 library"
HOMEPAGE="https://wiki.gnome.org/Projects/gexiv2"
@@ -18,9 +18,9 @@ else
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
fi
LICENSE="LGPL-2.1"
LICENSE="LGPL-2.1+ GPL-2"
SLOT="0"
IUSE="gtk-doc +introspection python static-libs test vala"
IUSE="gtk-doc +introspection python static-libs test +vala"
REQUIRED_USE="
python? ( introspection ${PYTHON_REQUIRED_USE} )
@@ -46,9 +46,8 @@ BDEPEND="
"
src_prepare() {
xdg_environment_reset
use vala && vala_src_prepare
default
use vala && vala_src_prepare
}
src_configure() {
@@ -56,8 +55,8 @@ src_configure() {
$(meson_use introspection)
$(meson_use vala vapi)
$(meson_use gtk-doc gtk_doc)
# prevents installation of python modules (uses install_data from meson
# which does not optimize the modules
# Prevents installation of python modules (uses install_data from meson
# which does not optimize the modules)
-Dpython2_girdir=no
-Dpython3_girdir=no
)