app-cdr/dolphin-plugins-mountiso: 24.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-cdr/dolphin-plugins-mountiso/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-24.08.3.tar.xz 317540 BLAKE2B 54fa2e13be2cceb53b12b1edb2d6d7c1793f6ba2bbec67e9e00121b33683aa6bd4895392cbdf5aa7627958c6323984ae3db8b5bbf6b14faba86b13181e0a2614 SHA512 05da7ac7b3ebe085cf0808d8e1eba49372bfeb1488800f40c1d0b9025e743efede1200095a1e660c1d538b2cc1b19f0f717f3d0723043517859f5c2015f961ce
+DIST dolphin-plugins-24.12.0.tar.xz 319128 BLAKE2B c793b10b882029eb7b2b681f15220fa065c2f59e4a1aa35ecf6ebfee253c4bd68aaf32c6555a8e03dad0ec8de7fba824834f1c0cbcb88c0c702b731b3d9b78d8 SHA512 94b4f8cd785c380b915da0e4a8efb9521d3a8440246466e4903746a2eb44188f1ae8cf3b483ec901f70c49c60a391de7c09d567e9a1a905b4229378c2623ee42

app-cdr/dolphin-plugins-mountiso/dolphin-plugins-mountiso-24.12.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY="sdk"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="mountiso"
+KFMIN=6.5.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.7.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for ISO loopback device mounting"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# qtconcurrent only required by git
+	ecm_punt_qt_module Concurrent
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_makefileactions=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}