dev-python/pdm: Bump to 2.10.4

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pdm/Manifest

@@ -1,2 +1,3 @@
 DIST pdm-2.10.1.tar.gz 2588192 BLAKE2B ce285679d727e4f8dfe0acb9503306871d36e7a358f38dec30db24f9ce69bc0e5089546ae3140757d68d36b698252d97434d18e51377469308e4059671569e06 SHA512 9f4f47586c1452feeb79f45b127ee799206564795ca238f0e69abff5d14e096af5583eb3749cc2635dfc15e883353c885e796f614195efdf58e08f77637b42f2
 DIST pdm-2.10.3.tar.gz 2588935 BLAKE2B 9c66f5928f6cd9cdacc5dec9490e0e96221ad8c4884c6b21e8b9d658f4e5c650dd2e9e415788ec3097403a0301c7baa8a7316dd0f3f0070708489dd394ed80bc SHA512 09a08a6f225a346d841ebadd394ac4d86313369de6482f4caf15cc401b7deb5b928bf5894178d1334596c430f3f14b87f8e29d15ec5d73e1f7d40be717211ddc
+DIST pdm-2.10.4.tar.gz 2589461 BLAKE2B 83366412f8b222067b33386a1a8fb0759945d22814da96b4c20e3a9bc459d6ad37f51e87720032249090c13e333becc33f4da482338c494af5fa49a578d4c308 SHA512 7e165f497a1cf1993554277ccf347410893f7635748d8d5a43dba1bc6156ea7655045c6ac865b96ff2e44d736b963fde5921a4710628201dd88c20d4fa7014f2

dev-python/pdm/pdm-2.10.4.ebuild

@@ -0,0 +1,79 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/truststore[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.12.1[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.4.0[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/tomli[${PYTHON_USEDEP}]' pypy3 python3_10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/cli/test_build.py::test_build_with_no_isolation[False]'
+		tests/test_project.py::test_access_index_with_auth
+		tests/cli/test_others.py::test_build_distributions
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[-e file:///${PROJECT_ROOT}/tests/fixtures/projects/demo-#-with-hash#egg=demo]'
+		# hangs on interactive keyring prompts
+		tests/cli/test_config.py::test_repository_overwrite_default
+		tests/cli/test_config.py::test_hide_password_in_output_repository
+		tests/cli/test_config.py::test_hide_password_in_output_pypi
+		# junk output, sigh
+		tests/cli/test_others.py::test_info_command_json
+		# why does it try to use python 2.7?!
+		tests/cli/test_run.py::test_import_another_sitecustomize
+	)
+	[[ ${EPYTHON} != python3.10 ]] && EPYTEST_DESELECT+=(
+		# test seems hardcoded to 3.10
+		tests/test_project.py::test_project_packages_path
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest  -m "not network and not integration and not path" \
+		-p pytest_mock
+}