net-dns/knot: drop 3.4.9-r1, 3.5.3

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1154
Merges: https://codeberg.org/gentoo/gentoo/pulls/1154
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Nicolas PARLANT
2026-06-14 17:09:27 +01:00
committed by Sam James
parent 8d66156c83
commit f1e118ea5f
3 changed files with 0 additions and 479 deletions
-6
View File
@@ -1,12 +1,6 @@
DIST knot-3.4.10-manpages.tar.xz 38344 BLAKE2B a80cbfdfc14d93e714425e65fe26f77ed64c1507930f0954a63fcf4e34d367ebc4cfc9c9ec5bae17efb3628271f0ee387d518f4f8bad89e5680d79b6e0b3eeab SHA512 19ff1b167471ab85370c4ce319df24716b9756bfafa520e43457e3dc1b5897e8da7bd0f64d066d5835e3e85bd34cc50af1e0d0dae8aa5d76d777f8ee66838f49
DIST knot-3.4.10.tar.xz 1664412 BLAKE2B 6c1e2c9d66551002fd8534b40714790e8ce455c6e91f198bfd50a98ef2edbf0d6ace8aa3055e006ba0869ac8e62f06ec06523051d452dacd6d5e31e6b5d42721 SHA512 836fd79f0db00013450056d01490c560cd6b195438a1b07024db802354a85b638b81937f9f738c45055626e48d84db3069865ecb2509f87a3a3deca7c9e1eeb1
DIST knot-3.4.10.tar.xz.asc 833 BLAKE2B c9faf63c4f679698d6175e99859107e9bb2de7936e8ddf70ed2aefa778864cc6463cd3f68366115a45a568dbfdba1fb2930f50dc053b7acdba33f316023e3aa9 SHA512 648a2b6827505d43f244b64e34899805029558a2b4e059259e925852aea0203d4c2299a98cf656b36e4474000ba43cf399c957742831251614e77be19b5a63ef
DIST knot-3.4.9-manpages.tar.xz 38044 BLAKE2B 274e53e1eea937c653fba1df4c3de858428c1d791d547c815a4a23c20173cdca8dcb5b43f09c463a13d5dbaa7782c9cb7202cb779be1e7f75152be9bfaad3a06 SHA512 183739249acfc4152631eb2227497d5f366a557762268af2800f641c1562a7b7a9b4135bf20ae834168994215bc528962dd87752a86fd92cda3f0a4e00644cd2
DIST knot-3.4.9.tar.xz 1622872 BLAKE2B 8188c3230fda2991a59157ab3168a156b42943be092e097b9f415879cb33d1d93ac989b1148793ad8a6900889ab88c0e7f288b96f3b52531e8b5b9636cc57703 SHA512 295bf54a28c98019fdcc4eb4382b27083b4239993624fdaab505afe2d00ec35d5e6f480ad5987a33e95cd604c5fbdf05ac2552377c7e0c389bbb0de35c658045
DIST knot-3.4.9.tar.xz.asc 833 BLAKE2B e6104ac0c20f83f472f5b7fd9cb9c214f1708f4f451ef00022bf256774c43655314f0f749cc82797f11e2d048e598f2342b36e0b62fbe5b3c9cac9a7ef341c5e SHA512 6d5898c8c04b9e50453cc8787cae533988b069b1d2dbbbe3f99a970de090d0790460fd28b7c88e3b194e3341f915cb4cf299ad7b32adc79fdb84b3c0eecb1a62
DIST knot-3.5.3-manpages.tar.xz 40396 BLAKE2B cff85410db872ffb3c3ecc31a6b3320a11d4511b4c2eccb5bc19cd76cdc9fe001353f8db2e01cd11ec0b2e32972c0209599a1d260b1c8cf961c21db5efcaabda SHA512 ab4ecb8b482a1d8cb60bc113499fe17a20404e9c0385d6e9ebc1600ed2ec3858761c5ca4d09b7636e7eaf0a7ff5ab298fc4cb9706a357b9ce47e7acbd51e72c3
DIST knot-3.5.3.tar.xz 1757736 BLAKE2B eff117f72248b6647eb54a2f0c230b971065205ab6adf2503785efdf045ae548568a95915bfbd594e99501ff7c8ca691e98f372ba4b1f88521ab685e015b4b3b SHA512 7064a18ce10fa9488176592baddfda32b55f6ca2470dce4083c82aca8fae95f568cb9ddd2bb9f55466eeffbb04ea616e67014f44b94f2fb2b8f98f8a419271a3
DIST knot-3.5.3.tar.xz.asc 833 BLAKE2B 661b74b7a460d9993226862d1f7dc2d74ca9e7f9a0057b5f9eae5c4748a2fdc16415212e209a8264e0d49ea4107e6a713ccaba3d3bb91deec3b3e86cc48e1237 SHA512 4ad40aaba569b4e6ccf3b6f264d3e45866855d5c388f6bd8140704ad9db09ef71d271c59704ca8e92bd39c0e7d62894d535b1f4e0642d1db33d113855ac6d6bd
DIST knot-3.5.4-manpages.tar.xz 40732 BLAKE2B a654321bd36003c9688e15f4b10cd35a800510c1c47bb8a46127e5ffb404401acb43de7ef75944ce17dc8d852d49eab52d4e98210dd09a12ed8c337b061776f8 SHA512 9bea474b273176649fee3e3643ddf35670981c53b6c6d5c9496843eb3705e450d9018790e3381179097e520ffcf6ae0150822b6561b1666a478431d73e8fb427
DIST knot-3.5.4.tar.xz 1767940 BLAKE2B ddd7b2fdcc2fbd23c3ff3173026883bae4b068eac7b076a641353a0c2f13b525914c6d8df3ea41b339667c28f4f5e70486b51fc7b6eee2de7bdf648b3ec2d3c8 SHA512 2dd51cc2d5c80a9570a8cd89cf094e7445ba60cc44df8152a932da5be2e8734a4c3916d6c36e6dea74031afab5d2af52e64bc7ce9efb93efe752c54ad5a3a818
DIST knot-3.5.4.tar.xz.asc 833 BLAKE2B c004654493b527cd2f788257d9b7b0169afd3ad36e862a321c4fc68468d379ebbbd7d1433d42c800d30164997f1e9660066b48c92dc7f29415322837d71374a4 SHA512 10da9849134a07303a075d26a9c3a5e59528f8251b250874e34404d71432115f9f1f98c059cf48fb42361f30fb7bbdc0de013f3d2e3ffa8a663bc78048e7e7bd
-231
View File
@@ -1,231 +0,0 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{11..14} )
inherit autotools python-r1 systemd tmpfiles verify-sig
# subslot: libknot major.libdnssec major.libzscanner major
KNOT_SUBSLOT="15.9.4"
DESCRIPTION="High-performance authoritative-only DNS server"
HOMEPAGE="https://www.knot-dns.cz/ https://gitlab.nic.cz/knot/knot-dns"
SRC_URI="
https://knot-dns.nic.cz/release/${P}.tar.xz
!doc? ( https://raw.githubusercontent.com/PPN-SD/gentoo-manpages/refs/tags/${P}/${P}-manpages.tar.xz )
verify-sig? ( https://knot-dns.nic.cz/release/${P}.tar.xz.asc )
"
LICENSE="GPL-3+"
SLOT="0/${KNOT_SUBSLOT}"
KEYWORDS="amd64 ~arm64 ~riscv x86"
# Modules without dep. Built unconditionally.
KNOT_MODULES=(
"authsignal"
"cookies"
"dnsproxy"
"noudp"
"onlinesign"
"queryacl"
"rrl"
"stats"
"synthrecord"
"whoami"
)
KNOT_MODULES_OPT=(
"dnstap"
"geoip"
)
IUSE="caps +daemon dbus doc doh +fastparser +idn pkcs11 prometheus python quic selinux systemd test +utils xdp ${KNOT_MODULES_OPT[@]}"
RESTRICT="!test? ( test )"
REQUIRED_USE="
prometheus? ( python )
python? ( ${PYTHON_REQUIRED_USE} )
"
COMMON_DEPEND="
dev-libs/libedit
dnstap? (
dev-libs/fstrm
dev-libs/protobuf-c:=
)
"
RDEPEND="
dev-db/lmdb:=
net-libs/gnutls:=[pkcs11?]
daemon? (
${COMMON_DEPEND}
acct-group/knot
acct-user/knot
dev-libs/userspace-rcu:=
caps? ( sys-libs/libcap-ng )
dbus? ( sys-apps/dbus )
geoip? ( dev-libs/libmaxminddb:= )
systemd? ( sys-apps/systemd:= )
)
prometheus? (
dev-python/prometheus-client[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
)
python? ( ${PYTHON_DEPS} )
quic? ( net-libs/ngtcp2[gnutls] )
selinux? ( sec-policy/selinux-knot )
utils? (
${COMMON_DEPEND}
doh? ( net-libs/nghttp2:= )
idn? ( net-dns/libidn2:= )
)
xdp? (
>=dev-libs/libbpf-1.0:=
net-libs/xdp-tools
utils? ( net-libs/libmnl:= )
)
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? (
$(python_gen_any_dep '
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx-panels[${PYTHON_USEDEP}]
')
)
python? ( ${PYTHON_DEPS} )
test? (
pkcs11? ( dev-libs/softhsm )
)
verify-sig? ( sec-keys/openpgp-keys-knot )
"
PATCHES=(
# PR 1830 merged
"${FILESDIR}"/${PN}-3.5.2-fix_automagic_pkcs11.patch
)
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/${PN}.asc
# Used to check cpuset_t in sched.h with NetBSD.
# False positive because linux have sched.h too but with cpu_set_t
QA_CONFIG_IMPL_DECL_SKIP=( cpuset_create cpuset_destroy )
python_check_deps() {
use doc || return 0
python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" \
"dev-python/sphinx-panels[${PYTHON_USEDEP}]"
}
pkg_setup() {
if use doc || use python; then
python_setup
fi
}
src_unpack() {
if use verify-sig; then
verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.asc}
fi
default
}
src_prepare() {
default
# avoid the old ltmain.sh modified by upstream which causes a linking issue
# reproduced with test and musl
eautoreconf
}
src_configure() {
local u
local my_conf=(
--with-storage="${EPREFIX}/var/lib/${PN}"
--with-rundir="${EPREFIX}/var/run/${PN}"
$(use_enable caps cap_ng)
$(use_enable daemon)
# enable-dnstap defines support for kdig only
$(use_enable dnstap dnstap $(usex utils))
$(use_enable doc documentation)
$(use_with doh libnghttp2)
$(use_enable fastparser)
$(use_enable geoip maxminddb)
$(use_with idn libidn)
$(use_enable pkcs11)
$(use_enable quic)
$(use_enable systemd)
$(use_enable utils utilities)
$(use_enable xdp)
)
# modules are only used by daemon
# module-dnstap defines support for knotd only
if use daemon; then
for u in "${KNOT_MODULES[@]}"; do
my_conf+=( --with-module-${u} )
done
for u in "${KNOT_MODULES_OPT[@]#+}"; do
my_conf+=( $(use_with ${u} module-${u}) )
done
else
my_conf+=( --disable-modules )
fi
if use !daemon; then
my_conf+=( --enable-dbus=no )
elif use dbus; then
my_conf+=( --enable-dbus=libdbus )
elif use systemd; then
my_conf+=( --enable-dbus=systemd )
else
my_conf+=( --enable-dbus=no )
fi
econf "${my_conf[@]}"
}
src_compile() {
default
use doc && emake -C doc html
}
src_install() {
if use doc; then
local HTML_DOCS=( doc/_build/html/{*.html,*.js,_sources,_static} )
else
doman "${WORKDIR}"/man/*
fi
if use python; then
python_foreach_impl python_domodule python/libknot/libknot
newdoc python/libknot/README.md README.python.md
fi
if use prometheus; then
python_foreach_impl python_domodule python/knot_exporter/knot_exporter
python_scriptinto /usr/sbin
python_foreach_impl python_newscript python/knot_exporter/knot_exporter/knot_exporter.py knot-exporter
newdoc python/knot_exporter/README.md README.knot_exporter.md
fi
default
if use daemon; then
rm -r "${ED}"/var/run/ || die
newinitd "${FILESDIR}"/knot-3.init knot
newconfd "${FILESDIR}"/knot.confd knot
newtmpfiles "${FILESDIR}"/${PN}.tmpfile ${PN}.conf
use systemd && systemd_newunit distro/common/knot.service knot.service
fi
find "${D}" -name '*.la' -delete || die
keepdir /var/lib/knot
}
pkg_postinst() {
use daemon && tmpfiles_process ${PN}.conf
}
-242
View File
@@ -1,242 +0,0 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{11..14} )
inherit autotools eapi9-ver python-r1 systemd tmpfiles verify-sig
# subslot: libknot major.libdnssec major.libzscanner major
KNOT_SUBSLOT="16.10.5"
DESCRIPTION="High-performance authoritative-only DNS server"
HOMEPAGE="https://www.knot-dns.cz/ https://gitlab.nic.cz/knot/knot-dns"
SRC_URI="
https://knot-dns.nic.cz/release/${P}.tar.xz
!doc? ( https://raw.githubusercontent.com/PPN-SD/gentoo-manpages/refs/tags/${P}/${P}-manpages.tar.xz )
verify-sig? ( https://knot-dns.nic.cz/release/${P}.tar.xz.asc )
"
LICENSE="GPL-2+"
SLOT="0/${KNOT_SUBSLOT}"
KEYWORDS="amd64 ~arm64 ~riscv x86"
# Modules without dep. Built unconditionally.
KNOT_MODULES=(
"authsignal"
"cookies"
"dnsproxy"
"noudp"
"onlinesign"
"queryacl"
"rrl"
"stats"
"synthrecord"
"whoami"
)
KNOT_MODULES_OPT=(
"dnstap"
"geoip"
)
IUSE="caps +daemon dbus doc doh +fastparser +idn pkcs11 prometheus python quic redis selinux systemd test +utils xdp ${KNOT_MODULES_OPT[@]}"
RESTRICT="!test? ( test )"
REQUIRED_USE="
prometheus? ( python )
python? ( ${PYTHON_REQUIRED_USE} )
"
COMMON_DEPEND="
dev-libs/libedit
dnstap? (
dev-libs/fstrm
dev-libs/protobuf-c:=
)
"
RDEPEND="
dev-db/lmdb:=
net-libs/gnutls:=[pkcs11?]
daemon? (
${COMMON_DEPEND}
acct-group/knot
acct-user/knot
dev-libs/userspace-rcu:=
caps? ( sys-libs/libcap-ng )
dbus? ( sys-apps/dbus )
geoip? ( dev-libs/libmaxminddb:= )
redis? ( >=dev-libs/hiredis-1.1.0:= )
systemd? ( sys-apps/systemd:= )
)
prometheus? (
dev-python/prometheus-client[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
)
python? ( ${PYTHON_DEPS} )
quic? ( net-libs/ngtcp2[gnutls] )
selinux? ( sec-policy/selinux-knot )
utils? (
${COMMON_DEPEND}
doh? ( net-libs/nghttp2:= )
idn? ( net-dns/libidn2:= )
)
xdp? (
>=dev-libs/libbpf-1.0:=
net-libs/xdp-tools
utils? ( net-libs/libmnl:= )
)
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
dnstap? (
dev-libs/protobuf[protoc(+)]
dev-libs/protobuf-c
)
doc? (
$(python_gen_any_dep '
dev-python/sphinx[${PYTHON_USEDEP}]
dev-python/sphinx-panels[${PYTHON_USEDEP}]
')
)
python? ( ${PYTHON_DEPS} )
test? (
pkcs11? ( dev-libs/softhsm )
)
verify-sig? ( sec-keys/openpgp-keys-knot )
"
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/${PN}.asc
# Used to check cpuset_t in sched.h with NetBSD.
# False positive because linux have sched.h too but with cpu_set_t
QA_CONFIG_IMPL_DECL_SKIP=( cpuset_create cpuset_destroy )
python_check_deps() {
use doc || return 0
python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" \
"dev-python/sphinx-panels[${PYTHON_USEDEP}]"
}
pkg_setup() {
if use doc || use python; then
python_setup
fi
}
src_unpack() {
if use verify-sig; then
verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.asc}
fi
default
}
src_prepare() {
default
# avoid the old ltmain.sh modified by upstream which causes a linking issue
# reproduced with test and musl
eautoreconf
}
src_configure() {
local u
local my_conf=(
--with-storage="${EPREFIX}/var/lib/${PN}"
--with-rundir="${EPREFIX}/var/run/${PN}"
$(use_enable caps cap_ng)
$(use_enable daemon)
# enable-dnstap defines support for kdig only
$(use_enable dnstap dnstap $(usex utils))
$(use_enable doc documentation)
$(use_with doh libnghttp2)
$(use_enable fastparser)
$(use_enable geoip maxminddb)
$(use_with idn libidn)
$(use_enable pkcs11)
$(use_enable quic)
$(use_enable redis redis $(usex daemon client))
$(use_enable systemd)
$(use_enable utils utilities)
$(use_enable xdp)
)
# modules are only used by daemon
# module-dnstap defines support for knotd only
if use daemon; then
for u in "${KNOT_MODULES[@]}"; do
my_conf+=( --with-module-${u} )
done
for u in "${KNOT_MODULES_OPT[@]#+}"; do
my_conf+=( $(use_with ${u} module-${u}) )
done
else
my_conf+=( --disable-modules )
fi
if use !daemon; then
my_conf+=( --enable-dbus=no )
elif use dbus; then
my_conf+=( --enable-dbus=libdbus )
elif use systemd; then
my_conf+=( --enable-dbus=systemd )
else
my_conf+=( --enable-dbus=no )
fi
econf "${my_conf[@]}"
}
src_compile() {
default
use doc && emake -C doc html
}
src_install() {
if use doc; then
local HTML_DOCS=( doc/_build/html/{*.html,*.js,_sources,_static} )
else
doman "${WORKDIR}"/man/*
fi
if use python; then
python_foreach_impl python_domodule python/libknot/libknot
newdoc python/libknot/README.md README.python.md
fi
if use prometheus; then
python_foreach_impl python_domodule python/knot_exporter/knot_exporter
python_scriptinto /usr/sbin
python_foreach_impl python_newscript python/knot_exporter/knot_exporter/knot_exporter.py knot-exporter
newdoc python/knot_exporter/README.md README.knot_exporter.md
fi
default
if use daemon; then
rm -r "${ED}"/var/run/ || die
newinitd "${FILESDIR}"/knot-3.init knot
newconfd "${FILESDIR}"/knot.confd knot
newtmpfiles "${FILESDIR}"/${PN}.tmpfile ${PN}.conf
use systemd && systemd_newunit distro/common/knot.service knot.service
fi
find "${D}" -name '*.la' -delete || die
keepdir /var/lib/knot
}
pkg_postinst() {
use daemon && tmpfiles_process ${PN}.conf
if has_version net-dns/redis-knot || use redis; then
ewarn "To use redis, ${EPREFIX}/usr/$(get_libdir)/knot/redis/knot.so from net-dns/redis-knot"
ewarn "must be loaded by an instance of Redis."
fi
if ver_replacing -lt 3.5; then
elog "See documentation for migration:"
elog "https://www.knot-dns.cz/docs/3.5/html/migration.html#upgrade-3-4-x-to-3-5-x"
fi
}