net-p2p/pybitmessage: 0.6.3.2_p20180521 snapshot bump

Bug: https://bugs.gentoo.org/653738
Package-Manager: Portage-2.3.40, Repoman-2.3.9

net-p2p/pybitmessage/Manifest

@@ -1,2 +1,3 @@
 DIST pybitmessage-0.4.2.tar.gz 547565 BLAKE2B 8cb7bc0407601f06c5d0040fa03372e95c34e21aed79021001f7067b3340c60a08f7ab7d2c6578e78e1f7bf09a5adc5805252a27cf8e1bda27de6d1495382e35 SHA512 5e783243db4f507ec221092f6da18d25bb15a8c83f28aab7c1796a063d2608c0115c9d636cc73b66a09264a4ff69dda9ba373eff81640b1dd9595100dcdc4917
 DIST pybitmessage-0.6.3.2_p20180326.tar.gz 1102343 BLAKE2B 55d1458858c1431f341feae10b151590bf8dc577d5a52e5ddfbb629853373339f80d0fb9a855cc82deb50ee952d7a356c0140b67ed1d28108a5c8f19d3b97305 SHA512 836dc5a2fbea96bd46bd50e6462ccb118f22591e9d838af80f05bcce3efa8434942b112725a0b5b161d9c0a544520931e56cfc01c33ea4d231bdc02c112c5894
+DIST pybitmessage-0.6.3.2_p20180521.tar.gz 1102349 BLAKE2B 346834ba6a6f7805ad79e95137b922b74963dd2c9da1b978e6e161be1e82b8465443ba1de255a6ab3c909c7ee1328509123eaf129dbafa13ec8c0d9f8291c93b SHA512 ef7e64e67cd6438fea1835db26c6ab71af004e1f6a7fb2cb8681674024a1addaeef1a31d959b1f0d3e502d8b96b3c07c6b6e0840e86dff12768ecd36e4fdf026

net-p2p/pybitmessage/pybitmessage-0.6.3.2_p20180521.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+
+COMMIT=30e211367003bafa67834ffff3f31e6b5a897f4b
+inherit distutils-r1 gnome2-utils
+
+MY_PN="PyBitmessage"
+
+DESCRIPTION="Reference client for Bitmessage: a P2P communications protocol"
+HOMEPAGE="https://bitmessage.org"
+SRC_URI="https://github.com/g1itch/${MY_PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug libnotify libressl ncurses opencl qrcode sound"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}"
+
+RDEPEND="${DEPEND}
+	|| (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/u-msgpack[${PYTHON_USEDEP}]
+	)
+	dev-python/PyQt5[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-1.3.1[gui,pyqt5(+),${PYTHON_USEDEP}]
+	debug? ( dev-python/python-prctl[${PYTHON_USEDEP}] )
+	libnotify? (
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		dev-python/notify2[${PYTHON_USEDEP}]
+		x11-themes/hicolor-icon-theme
+	)
+	!libressl? ( dev-libs/openssl:0[-bindist] )
+	libressl? ( dev-libs/libressl )
+	ncurses? ( dev-python/pythondialog[${PYTHON_USEDEP}] )
+	opencl? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pyopencl[${PYTHON_USEDEP}]
+	)
+	qrcode? ( dev-python/qrcode[${PYTHON_USEDEP}] )
+	sound? ( || (
+		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+		media-sound/gst123
+		media-libs/gst-plugins-base:1.0
+		media-sound/mpg123
+		media-sound/alsa-utils
+	) )
+"
+
+S="${WORKDIR}"/${MY_PN}-${COMMIT}
+
+src_install () {
+	distutils-r1_src_install
+	einstalldocs
+	# The man page is not installed because it's basically empty.
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}