dev-python/libcloud: Bump to 3.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/libcloud/Manifest

@@ -1 +1,2 @@
 DIST apache-libcloud-3.6.1.tar.bz2 1944060 BLAKE2B 61e1481cc8e4e3e017c262d20666ee33a79ccb78bbc0d682dfe6f63df26f21c06897ec98b0df56a27ac6ee92922a08ecb98451c1680c323f042a497379f91090 SHA512 292166aa1eda4b31eb1552c91d9acd54001c363471f1fdd5310e3e25519d7e1f599d9566f55a0c10ece08d544774e1abca3043283b1e7dd93bfadb7e36b02e22
+DIST apache-libcloud-3.7.0.tar.bz2 1979020 BLAKE2B f8630a5c559cba9ae6f7792ffc9cf4ba6eb2fdaa28d6ae148a5d2e978ee66eec9a39b16741446b78b047bf2454de860148a13bce3dbd8627dbc7dac43543b808 SHA512 315866947d2c748e4a13c4c2a4147a2a8e79cbb85e9e83fded3f89ff8a50c531acf1062a4e21c61448c20e7f7e7f9d1317d3c43ecfe2fb75155c0d81ff03f889

dev-python/libcloud/libcloud-3.7.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="https://libcloud.apache.org/"
+SRC_URI="mirror://apache/${PN}/apache-${P}.tar.bz2"
+S="${WORKDIR}/apache-${P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/pyopenssl[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-2.6.1[${PYTHON_USEDEP}]
+		dev-python/lockfile[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Needs network access
+	libcloud/test/compute/test_ovh.py::OvhTests::test_list_nodes_invalid_region
+	libcloud/test/test_connection.py::BaseConnectionClassTestCase::test_connection_timeout_raised
+	libcloud/test/test_connection.py::ConnectionClassTestCase::test_retry_on_all_default_retry_exception_classes
+	# TODO
+	libcloud/test/compute/test_ssh_client.py::ParamikoSSHClientTests::test_key_file_non_pem_format_error
+)
+
+src_prepare() {
+	if use examples; then
+		mkdir examples || die
+		mv example_*.py examples || die
+	fi
+
+	# needed for tests
+	cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	use examples && dodoc -r examples
+	distutils-r1_src_install
+}