xfce-base/xfconf: Bump to 4.18.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2022-12-15 16:03:57 +01:00
parent 030ceb7066
commit f1663019cd
2 changed files with 79 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST xfconf-4.16.0.tar.bz2 634858 BLAKE2B 34a03e457934310d4750b0811ff3b6fbde0c786656c9cc1bb2dd733e0104c2ab3ff1834fefcea31a6711931406b8ab507a528596b598e92c401defb8e6d7715e SHA512 d2e6b272243d6eda71f42cb3df18cb9c0745a1864718639e9aa494902dfe5b4989b2761fee2195456e5725cad0f744978f9c95c6f01e48aa016a919ce3468344
DIST xfconf-4.17.2.tar.bz2 625124 BLAKE2B 173f50ab3b0ded6b62bb421006588be662428928174786850591594b7d012ff432945643f514f00195919bc8f5b36e4d2524c27984378e8850580d518a1f4b05 SHA512 2861d58a2007c44745cef7829a6eaf689b72142dcfa25c0a7cebf984ed599e2cb238589ef682da1d7b9fdb99cc0c250a26a68a46553c53e303ac546850f14486
DIST xfconf-4.18.0.tar.bz2 625755 BLAKE2B dac7ccd7052818436f45e6c257cc6076221d9f5d7c2d836d909be0d9479abd88f6c17748cf0aa65be79a0642c7bb7ebb01b6cd5a22bb22d514fc3ed57be5d4af SHA512 49ac3070e44e0c699c157e6c029bf14d932bc1e60b01bc3b4f7451acf403d451ac52e2dfb14fc97298cc774c7a0895616788cdbfc189976805669fcdb7aa47b6
+78
View File
@@ -0,0 +1,78 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit bash-completion-r1 vala
DESCRIPTION="A configuration management system for Xfce"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
HOMEPAGE="
https://docs.xfce.org/xfce/xfconf/start
https://gitlab.xfce.org/xfce/xfconf/
"
LICENSE="GPL-2+"
SLOT="0/3"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
IUSE="debug +introspection vala"
REQUIRED_USE="vala? ( introspection )"
DEPEND="
>=dev-libs/glib-2.66.0
sys-apps/dbus
>=xfce-base/libxfce4util-4.17.3:=
introspection? ( >=dev-libs/gobject-introspection-1.66:= )
"
RDEPEND="
${DEPEND}
"
BDEPEND="
dev-util/gdbus-codegen
dev-util/glib-utils
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
vala? ( $(vala_depend) )
"
src_configure() {
local myconf=(
$(use_enable introspection)
$(use_enable vala)
$(use_enable debug checks)
--with-bash-completion-dir="$(get_bashcompdir)"
)
use vala && vala_setup
econf "${myconf[@]}"
}
src_test() {
local service_dir=${HOME}/.local/share/dbus-1/services
mkdir -p "${service_dir}" || die
cat > "${service_dir}/org.xfce.Xfconf.service" <<-EOF || die
[D-BUS Service]
Name=org.xfce.Xfconf
Exec=${S}/xfconfd/xfconfd
EOF
(
# start isolated dbus session bus
dbus_data=$(dbus-launch --sh-syntax) || exit
eval "${dbus_data}"
# -j>1 often hangs
# https://gitlab.xfce.org/xfce/xfconf/-/issues/13
nonfatal emake -j1 check
ret=${?}
kill "${DBUS_SESSION_BUS_PID}"
exit "${ret}"
) || die
}
src_install() {
default
find "${D}" -type f -name '*.la' -delete || die
}