media-video/parole: Bump to 4.20.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

media-video/parole/Manifest

@@ -1 +1,2 @@
 DIST parole-4.18.2.tar.bz2 1183723 BLAKE2B b7222cbe0271408987869d924f83343c1b599e700952b6b094d7ac5566c3d6c1135ed84a06037a07a6d60c899f92e19f6e67ccc778f8525b859bffd28d0a7007 SHA512 856a8430882f3b4410cb719702eabdc9754b9511cc21cb61d86d033fb1b623442affb4e1ec569adecd414413eecb604553b5256525165c7eeda1b3d598330673
+DIST parole-4.20.0.tar.xz 481288 BLAKE2B 3573230fef11c76491c2f45ddaaad24e993239e23b1dca968c41873f4abfe1b4e21b2ddd70cd2a5438866915d2b49a6dfa3402f94ae61eeb6323db2e9859761d SHA512 a39438cf3684dee84406fce5aed7c4b30e0fd726e9c7399a015a67f32d7a1ca9af1a543147a96e13113545996e27c44586daf4df013fb81df4b8c4c348bf93a6

media-video/parole/parole-4.20.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="A simple Xfce4 media player using GStreamer"
+HOMEPAGE="
+	https://docs.xfce.org/apps/parole/start
+	https://gitlab.xfce.org/apps/parole/
+"
+SRC_URI="
+	https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.xz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="gtk-doc libnotify taglib wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=dev-libs/dbus-glib-0.70
+	>=dev-libs/glib-2.38.0:2
+	>=media-libs/gstreamer-1.0.0:1.0
+	>=media-libs/gst-plugins-base-1.0.0:1.0
+	>=sys-apps/dbus-0.60
+	>=x11-libs/gtk+-3.22.0:3[wayland?,X?]
+	>=xfce-base/libxfce4ui-4.16.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.16.0:=
+	>=xfce-base/xfconf-4.16.0:=
+	libnotify? ( >=x11-libs/libnotify-0.7.8 )
+	taglib? ( >=media-libs/taglib-1.4:0= )
+	X? (
+		>=x11-libs/libX11-1.6.7
+	)
+"
+RDEPEND="
+	${DEPEND}
+	media-plugins/gst-plugins-meta:1.0
+"
+DEPEND+="
+	x11-base/xorg-proto
+"
+# dev-libs/dbus-glib for dbus-binding-tool
+# dev-libs/glib for glib-compile-resources
+BDEPEND="
+	dev-libs/dbus-glib
+	>=dev-libs/glib-2.38.0:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+		$(meson_feature taglib)
+		-Dmpris2-plugin=enabled
+		$(meson_feature libnotify notify-plugin)
+		-Dtray-plugin=enabled
+		$(meson_use gtk-doc)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}