gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

games-rpg/manaplus: Bump to version 1.8.2.17

Browse Source 
Package-Manager: Portage-2.3.24, Repoman-2.3.6
This commit is contained in:
Lars Wendler
2018-02-22 11:27:17 +01:00
parent 25c1bfe2aa
commit f08dedfeb5
2 changed files with 100 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
games-rpg/manaplus/Manifest
View File

@@ -1 +1,2 @@
DIST manaplus-1.7.11.11.tar.xz 14940736 BLAKE2B 42746df8f51808745e1e964419a6e5ad6d5f7e06adec2dc80956e4060fadb55f42150359637ea612919327c8fc4b5261d208b6837e47c310ec6e254cd99eee7f SHA512 d5b14cb0e9859a76abb9a6fb4e8761704e66ff145ba5e46b616aee43a58197bb2b28a4d81e9cdb49a9aaf295241d0730f123cfabd2a9a720d786826ee811ab40
DIST manaplus-1.8.2.17.tar.xz 14982240 BLAKE2B 8ed41c0af49ed3c3bfce69e4c29fc4a3a555fbda1cb05f2c3fb6395c74cdca4d22e890422137573a6b308d3cfe09416892bc6850f11469a267d9419a44b112a8 SHA512 b67a7e5986b5aa9716e4ae4ee651e63445f11e7efe258726d8f7c5245ebc9e5da9b4b65fb561023bfcca492098f3a6da9cac77e5ace27a4b7b0a7245e38ac08d

99
games-rpg/manaplus/manaplus-1.8.2.17.ebuild Normal file
View File

@@ -0,0 +1,99 @@
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
[[ ${PV} == 9999 ]] && inherit autotools git-r3
DESCRIPTION="OpenSource 2D MMORPG client for Evol Online and The Mana World"
HOMEPAGE="http://manaplus.evolonline.org"
if [[ ${PV} == 9999 ]] ; then
EGIT_REPO_URI="https://github.com/ManaPlus/ManaPlus.git"
else
SRC_URI="http://download.evolonline.org/manaplus/download/${PV}/${P}.tar.xz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2+"
SLOT="0"
IUSE="mumble nls opengl pugixml +sdl2 test"
RDEPEND="
>=dev-games/physfs-1.0.0
media-fonts/dejavu
media-fonts/liberation-fonts
media-fonts/mplus-outline-fonts
media-fonts/wqy-microhei
media-libs/libpng:0=
net-misc/curl
sys-libs/zlib
x11-apps/xmessage
x11-libs/libX11
x11-misc/xdg-utils
mumble? ( media-sound/mumble )
nls? ( virtual/libintl )
opengl? ( virtual/opengl )
pugixml? ( dev-libs/pugixml )
!pugixml? ( dev-libs/libxml2 )
sdl2? (
media-libs/libsdl2[X,opengl?,video]
media-libs/sdl2-gfx
media-libs/sdl2-image[png]
media-libs/sdl2-mixer[vorbis]
media-libs/sdl2-net
media-libs/sdl2-ttf
)
!sdl2? (
media-libs/libsdl[X,opengl?,video]
media-libs/sdl-gfx
media-libs/sdl-image[png]
media-libs/sdl-mixer[vorbis]
media-libs/sdl-net
media-libs/sdl-ttf
)"
DEPEND="${RDEPEND}
virtual/pkgconfig
nls? ( sys-devel/gettext )"
src_prepare() {
default
if [[ ${PV} == 9999 ]] ; then
eautoreconf
fi
}
src_configure() {
local myeconfargs=(
--localedir=/usr/share/locale
--without-internalsdlgfx
$(use_with mumble)
$(use_enable nls)
$(use_with opengl)
--enable-libxml=$(usex pugixml pugixml libxml)
$(use_with sdl2)
$(use_enable test unittests)
)
CONFIG_SHELL=/bin/bash econf "${myeconfargs[@]}"
}
src_install() {
default
local destpath="/usr/share/${PN}"
dosym /usr/share/fonts/dejavu/DejaVuSans-Bold.ttf "${destpath}"/data/fonts/dejavusans-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSans.ttf "${destpath}"/data/fonts/dejavusans.ttf
dosym /usr/share/fonts/dejavu/DejaVuSansMono-Bold.ttf "${destpath}"/data/fonts/dejavusansmono-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSansMono.ttf "${destpath}"/data/fonts/dejavusansmono.ttf
dosym /usr/share/fonts/dejavu/DejaVuSerifCondensed-Bold.ttf "${destpath}"/data/fonts/dejavuserifcondensed-bold.ttf
dosym /usr/share/fonts/dejavu/DejaVuSerifCondensed.ttf "${destpath}"/data/fonts/dejavuserifcondensed.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationMono-Bold.ttf "${destpath}"/data/fonts/liberationsansmono-bold.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationMono-Regular.ttf "${destpath}"/data/fonts/liberationsansmono.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationSans-Bold.ttf "${destpath}"/data/fonts/liberationsans-bold.ttf
dosym /usr/share/fonts/liberation-fonts/LiberationSans-Regular.ttf "${destpath}"/data/fonts/liberationsans.ttf
dosym /usr/share/fonts/mplus-outline-fonts/mplus-1p-bold.ttf "${destpath}"/data/fonts/mplus-1p-bold.ttf
dosym /usr/share/fonts/mplus-outline-fonts/mplus-1p-regular.ttf "${destpath}"/data/fonts/mplus-1p-regular.ttf
dosym /usr/share/fonts/wqy-microhei/wqy-microhei.ttc "${destpath}"/data/fonts/wqy-microhei.ttf
}
src_test() {
make check
}