dev-python/python-efl: add 1.26.1

Closes: https://bugs.gentoo.org/909954
Closes: https://bugs.gentoo.org/896846
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

dev-python/python-efl/Manifest

@@ -1 +1,2 @@
 DIST python-efl-1.26.0.tar.xz 9547648 BLAKE2B b6fd9e86695569291b416140c92316aeb4e3bd42d12fc3fd656b86fe7fae364720c8457c53828dc00838a68620fa604426d86c5d4bce02e94eaa82a4fed120ee SHA512 fe552a65d7d4d3e3664310e6bb7189c883c64361a64a2def04e8d14df3e5a03211e2992333f1c05288b96f1d99f20ad4ac848baea91d43db280dad81315e2473
+DIST python-efl-1.26.1.tar.xz 9554132 BLAKE2B d08c9c695c3667e0d3b1b45b1c7026f1af6ca1c100235c1a412dfa354e549c45db75442693c1d7a3f68b6c63a47cf6d120fd3071856a6e7c7da51f0ccdb309b0 SHA512 42b7586885d47fc67bf3692e65325e58cb0566fb772b415255b2f63b05adfdcdc44762f532bc951781ece118833486b33dc5a3f0aa10e0a14d5226ca4dc30f9e

dev-python/python-efl/python-efl-1.26.1.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Python bindings for Enlightenment Foundation Libraries"
+HOMEPAGE="https://github.com/DaveMDS/python-efl https://docs.enlightenment.org/python-efl/current/"
+SRC_URI="https://download.enlightenment.org/rel/bindings/python/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="=dev-libs/efl-$(ver_cut 1-2)*
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	sys-apps/dbus"
+DEPEND="${RDEPEND}"
+BDEPEND="<dev-python/cython-3.0[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)"
+
+PATCHES=( "${FILESDIR}/python-efl-1.25-clang-crosscompile.patch" )
+
+src_prepare() {
+	default
+
+	# Generate our own C files, discard the bundled ones.
+	export ENABLE_CYTHON=1
+
+	# Tries to download a file under /tmp
+	rm tests/ecore/test_09_file_download.py || die
+
+	# Tries to use that file which failed to download
+	rm tests/ecore/test_10_file_monitor.py || die
+
+	# Needs an active internet connection
+	rm tests/ecore/test_11_con.py || die
+
+	# Test fails because of deleted files above
+	sed -i 's/>= 13/>= 10/g' tests/ecore/test_08_exe.py || die
+
+	# Make tests verbose
+	sed -i 's:verbosity=1:verbosity=3:' tests/00_run_all_tests.py || die
+
+	# Disable any optimization on x86, #704260
+	if use x86; then
+		filter-flags -O?
+		append-cflags -O0
+	fi
+}
+
+python_compile_all() {
+	if use doc ; then
+		${EPYTHON} -m sphinx.cmd.build doc "${S}"/build/doc/ || die "Building docs failed with ${EPYTHON}."
+	fi
+
+	${EPYTHON} setup.py build || die "src_compile failed with ${EPYTHON}"
+}
+
+python_test() {
+	cd tests/ || die
+	${EPYTHON} 00_run_all_tests.py --verbose || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( ./build/doc/. )
+	distutils-r1_python_install_all
+}