dev-util/vulkan-tools: Version bump to 1.4.313.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-util/vulkan-tools/Manifest

@@ -1 +1,2 @@
 DIST vulkan-tools-1.4.309.0.tar.gz 790704 BLAKE2B d339a15ad11b558904e4102da6bd74ce28b24217a4fed33543124c56fd5c84c656c126e50a56d36a06011a90e5dde006c2d36ce363fdedaf6093dfc12964486f SHA512 ff505ba27556261103664b50ee88d26efdd040d7e0168ec0a37cdcebf421fbf75f73bdae55282c1e82b913491abd365a61edf95a5b917eb0b20abf6f60b89742
+DIST vulkan-tools-1.4.313.0.tar.gz 799592 BLAKE2B 2826a170f6ef4eec686ce208570bd6ccd7d5f800543876e65b7207a86bfc704c7a92683110c21f1f05bed004a2452f9ca63227b1a50da07b50b6a13a7247be0d SHA512 7aed7191e5d9c27a7c710258bc92ccec8809f736a96d7b5e4eef756bf9e64c7c63987746edf180321acc9f60760451eef32e1578c9d100c1c6e9785ac9fbc6bb

dev-util/vulkan-tools/vulkan-tools-1.4.313.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Tools
+PYTHON_COMPAT=( python3_{11..14} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv"
+	S="${WORKDIR}"/${MY_PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Official Vulkan Tools and Utilities for Windows, Linux, Android, and MacOS"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Tools"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="cube wayland X"
+
+BDEPEND="${PYTHON_DEPS}
+	cube? ( ~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	~media-libs/vulkan-loader-${PV}[${MULTILIB_USEDEP},wayland?,X?]
+	wayland? ( dev-libs/wayland[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libxcb:=[${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	~dev-util/vulkan-headers-${PV}
+	X? ( x11-libs/libXrandr[${MULTILIB_USEDEP}] )
+"
+
+pkg_setup() {
+	MULTILIB_CHOST_TOOLS=(
+		/usr/bin/vulkaninfo
+	)
+
+	use cube && MULTILIB_CHOST_TOOLS+=(
+		/usr/bin/vkcube
+		/usr/bin/vkcubepp
+	)
+
+	python-any-r1_pkg_setup
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_VULKANINFO=ON
+		-DBUILD_CUBE=$(usex cube)
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DVULKAN_HEADERS_INSTALL_DIR="${ESYSROOT}/usr"
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	if use cube; then
+		einfo "As of version 1.4.304.0, the window system for 'vkcube' and 'vkcubepp'"
+		einfo "can be selected at runtime using the '--wsi' runtime argument."
+		einfo "For example, Wayland can be selected using '--wsi wayland'."
+		einfo "As such, 'vkcube-wayland' has been removed and the runtime argument"
+		einfo "must be used instead. See 'vkcube --help' for more information."
+	fi
+}