mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-fs/samba: Bump to version 4.4.4
Package-Manager: portage-2.2.28 Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
This commit is contained in:
Lars Wendler
@@ -6,6 +6,7 @@ DIST samba-4.2.12.tar.gz 20878216 SHA256 b334a86a92a1c2759c0b3dce20965e7fe820f0a
|
||||
DIST samba-4.2.9.tar.gz 20750339 SHA256 ba0229485e8bebac22bd3ae98b1e393e7127f3a958cc90e205a6d752e575354c SHA512 438196f268c0ca0b83e8e7e9eb8e9a8b503d6408d5e2b0dca1d041185e06cfc08147122d5495b72c46ce58dc3cb4be4766551f0101c69b2620b89e749d89ad98 WHIRLPOOL aa7a655a3d2f2bf81d2747d83c86a0c7d464a31414b6e27a413461e1e0ad0ce3d3af5d756d8ce213e775f5141c44ef9c41a792e88d246bcab002b7623552260a
|
||||
DIST samba-4.3.9.tar.gz 20570849 SHA256 1f22c61a7f24c5357a9ef4d10833a2cd161f40f3db03bcbe586d7cd3a56139f3 SHA512 bc90c88d8defd3acec7c671e8ceacec31e3111540aabee7ec6f11cdeaf61bbd993525e2b765e3b50801c8079e1168cf496b3e5e6a56118d6493ae5da60d34c41 WHIRLPOOL e33efba4bfbaab5278ec62cbadb5f14fe2220d4b4ad1e57a4d26233d8b6bdf4318ad86d839b2638a490a195c04aabb02dafff67bb1e2999fab4f116b3c6367cc
|
||||
DIST samba-4.4.3.tar.gz 20705861 SHA256 031e6ada6d15deae6850845eed41497af32207fb679d6c6c74f19acc99d437ba SHA512 25c447f476a54c7e5992d3010957401373eb99b89bcab3e80d7a5aee08413fab87d0dc87d43e7c541b4fa1778a8707121639f56a208dd634e0b1f905eb8afa7c WHIRLPOOL 4c62e58cf9d851ca114f3d3eea20350a589006acbe5fb9209c7be0617f435cee0c4a706906238a354a78d97aa6fdd45d40aef699a2c179ced3671f996fb2afc7
|
||||
DIST samba-4.4.4.tar.gz 20711340 SHA256 262f9edabbd1c0112819b5063718588c22b0ee4c1a2f648f79f233fdfba25c8b SHA512 e982c09051fd4e7a14abfe4ae5add3d8da61e4e761511a403c911fadc3d8809dad19d5591c71baa35f80fe5c07b4fa67b46b6565aa03144c57d5a17476bb343b WHIRLPOOL 9a214aedcaefc66cb5e34a73544986ae31c12061e4b3f7f3958ec4d16e7b6db92650ee4b77f426418124461bcdd7ecde31e6bbe0b5ee95dea7cfd3cb12e4b4a9
|
||||
DIST samba-disable-python-patches-4.2.12.tar.xz 6052 SHA256 8903eacbabdfaf7b64cbde03d7c367d1efdc92e54090f0f4b9ed5d2a462b1c18 SHA512 c527d0a052d3211e5b12c17bc94db56cc5e5545189ed65a760c0656c94c22e27a4b159e6439eb0370873e1619873a741f3b3bd10d3876b38eb3914a87eace372 WHIRLPOOL ad63db55d5dc96f56e6c9b30c2092e2f6e206b0ed5d13c249879d10753c8db2f475c5d4e651e2fc042ad992b648d3b4465f1b28c6b4bbf821cf503d27f741f7e
|
||||
DIST samba-disable-python-patches-4.2.9.tar.xz 6016 SHA256 222d0153f03dddde28a0b906ee2b27076223ac88b84a998aaa285f658861edfa SHA512 02fc666a36f8e733e522663d80775d130fabee9d5fb4e1c261d28815e07be425ae8977213f9216c7af62dd8b2619e7e13d71f9a25780b058c8119901c2115a18 WHIRLPOOL ebba3a6d41a41844621759672aa8c984d26f44d12007c8e929405470c381bc262523ec68d3972e86cf675c45f092fa287496167e42940e70d704790753e47b03
|
||||
DIST samba-disable-python-patches-4.3.9.tar.xz 6116 SHA256 83206112e04c375e170e86ea6b29d6dc2c172b55ba9fb89130be14708d758cf5 SHA512 ca8b62337afd1cc6059b9aefc0a3972d18ba90fba3f043d9730f6967e1b80c40bc918b0445b8ae8a1f3df74d3551f90c721df3c0514edccb881ed0b4fc54e1b5 WHIRLPOOL 3aebd6758e5e7dc2920b1e8f8825d2b7b7efac7c5f2d91d5ed6fed75597bfdced1b27d9e2a00385af5df19e5462a4e014df6a7274c0b25a660702268235ef746
|
||||
|
||||
233
net-fs/samba/samba-4.4.4.ebuild
Normal file
233
net-fs/samba/samba-4.4.4.ebuild
Normal file
@@ -0,0 +1,233 @@
|
||||
# Copyright 1999-2016 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
# $Id$
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python2_7 )
|
||||
PYTHON_REQ_USE='threads(+),xml(+)'
|
||||
|
||||
inherit python-single-r1 waf-utils multilib-minimal linux-info systemd eutils
|
||||
|
||||
MY_PV="${PV/_rc/rc}"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
|
||||
SRC_PATH="stable"
|
||||
[[ ${PV} = *_rc* ]] && SRC_PATH="rc"
|
||||
|
||||
SRC_URI="mirror://samba/${SRC_PATH}/${MY_P}.tar.gz
|
||||
https://dev.gentoo.org/~axs/distfiles/samba-disable-python-patches-4.4.2.tar.xz"
|
||||
[[ ${PV} = *_rc* ]] || \
|
||||
KEYWORDS="~amd64 ~hppa ~x86"
|
||||
|
||||
DESCRIPTION="Samba Suite Version 4"
|
||||
HOMEPAGE="http://www.samba.org/"
|
||||
LICENSE="GPL-3"
|
||||
|
||||
SLOT="0"
|
||||
|
||||
IUSE="acl addc addns ads avahi client cluster cups dmapi fam gnutls iprint
|
||||
ldap pam quota selinux syslog +system-mitkrb5 systemd test winbind"
|
||||
|
||||
MULTILIB_WRAPPED_HEADERS=(
|
||||
/usr/include/samba-4.0/policy.h
|
||||
/usr/include/samba-4.0/dcerpc_server.h
|
||||
/usr/include/samba-4.0/ctdb.h
|
||||
/usr/include/samba-4.0/ctdb_client.h
|
||||
/usr/include/samba-4.0/ctdb_protocol.h
|
||||
/usr/include/samba-4.0/ctdb_private.h
|
||||
/usr/include/samba-4.0/ctdb_typesafe_cb.h
|
||||
/usr/include/samba-4.0/ctdb_version.h
|
||||
)
|
||||
|
||||
# sys-apps/attr is an automagic dependency (see bug #489748)
|
||||
CDEPEND="${PYTHON_DEPS}
|
||||
>=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}]
|
||||
dev-lang/perl:=
|
||||
dev-libs/libbsd[${MULTILIB_USEDEP}]
|
||||
dev-libs/iniparser:0
|
||||
dev-libs/popt[${MULTILIB_USEDEP}]
|
||||
sys-libs/readline:=
|
||||
virtual/libiconv
|
||||
dev-python/subunit[${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
sys-apps/attr[${MULTILIB_USEDEP}]
|
||||
sys-libs/libcap
|
||||
>=sys-libs/ldb-1.1.26[${MULTILIB_USEDEP}]
|
||||
sys-libs/ncurses:0=[${MULTILIB_USEDEP}]
|
||||
>=sys-libs/talloc-2.1.6[python,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tdb-1.3.8[python,${PYTHON_USEDEP},${MULTILIB_USEDEP}]
|
||||
>=sys-libs/tevent-0.9.28[${MULTILIB_USEDEP}]
|
||||
sys-libs/zlib[${MULTILIB_USEDEP}]
|
||||
virtual/pam
|
||||
acl? ( virtual/acl )
|
||||
addns? ( net-dns/bind-tools[gssapi] )
|
||||
cluster? ( !dev-db/ctdb )
|
||||
cups? ( net-print/cups )
|
||||
dmapi? ( sys-apps/dmapi )
|
||||
fam? ( virtual/fam )
|
||||
gnutls? ( dev-libs/libgcrypt:0
|
||||
>=net-libs/gnutls-1.4.0 )
|
||||
ldap? ( net-nds/openldap[${MULTILIB_USEDEP}] )
|
||||
system-mitkrb5? ( app-crypt/mit-krb5[${MULTILIB_USEDEP}] )
|
||||
!system-mitkrb5? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] )
|
||||
systemd? ( sys-apps/systemd:0= )"
|
||||
DEPEND="${CDEPEND}
|
||||
virtual/pkgconfig"
|
||||
RDEPEND="${CDEPEND}
|
||||
client? ( net-fs/cifs-utils[ads?] )
|
||||
selinux? ( sec-policy/selinux-samba )
|
||||
!dev-perl/Parse-Yapp
|
||||
"
|
||||
|
||||
REQUIRED_USE="addc? ( gnutls !system-mitkrb5 )
|
||||
ads? ( acl gnutls ldap )
|
||||
${PYTHON_REQUIRED_USE}"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-4.2.3-heimdal_compilefix.patch"
|
||||
"${FILESDIR}/${PN}-4.4.0-pam.patch"
|
||||
)
|
||||
|
||||
CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)"
|
||||
|
||||
WAF_BINARY="${S}/buildtools/bin/waf"
|
||||
|
||||
SHAREDMODS=""
|
||||
|
||||
pkg_setup() {
|
||||
python-single-r1_pkg_setup
|
||||
if use cluster ; then
|
||||
SHAREDMODS="${SHAREDMODS}idmap_rid,idmap_tdb2,idmap_ad"
|
||||
fi
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
# install the patches from tarball(s)
|
||||
eapply "${WORKDIR}/patches/"
|
||||
|
||||
multilib_copy_sources
|
||||
}
|
||||
|
||||
multilib_src_configure() {
|
||||
local myconf=()
|
||||
myconf=(
|
||||
--enable-fhs
|
||||
--sysconfdir=/etc
|
||||
--localstatedir=/var
|
||||
--with-modulesdir=/usr/$(get_libdir)/samba
|
||||
--with-piddir=/run/${PN}
|
||||
--bundled-libraries=NONE
|
||||
--builtin-libraries=NONE
|
||||
--disable-rpath
|
||||
--disable-rpath-install
|
||||
--nopyc
|
||||
--nopyo
|
||||
)
|
||||
if multilib_is_native_abi ; then
|
||||
myconf+=(
|
||||
$(use_with acl acl-support)
|
||||
$(usex addc '' '--without-ad-dc')
|
||||
$(use_with addns dnsupdate)
|
||||
$(use_with ads)
|
||||
$(usex ads '--with-shared-modules=idmap_ad' '')
|
||||
$(use_enable avahi)
|
||||
$(use_with cluster cluster-support)
|
||||
$(use_enable cups)
|
||||
$(use_with dmapi)
|
||||
$(use_with fam)
|
||||
$(use_enable gnutls)
|
||||
$(use_enable iprint)
|
||||
$(use_with ldap)
|
||||
$(use_with pam)
|
||||
$(usex pam "--with-pammodulesdir=/$(get_libdir)/security" '')
|
||||
$(use_with quota quotas)
|
||||
$(use_with syslog)
|
||||
$(use_with systemd)
|
||||
$(usex system-mitkrb5 '--with-system-mitkrb5' '')
|
||||
$(use_with winbind)
|
||||
$(usex test '--enable-selftest' '')
|
||||
--with-shared-modules=${SHAREDMODS}
|
||||
)
|
||||
else
|
||||
myconf+=(
|
||||
--without-acl-support
|
||||
--without-ad-dc
|
||||
--without-dnsupdate
|
||||
--without-ads
|
||||
--disable-avahi
|
||||
--without-cluster-support
|
||||
--disable-cups
|
||||
--without-dmapi
|
||||
--without-fam
|
||||
--disable-gnutls
|
||||
--disable-iprint
|
||||
$(use_with ldap)
|
||||
--without-pam
|
||||
--without-quotas
|
||||
--without-syslog
|
||||
--without-systemd
|
||||
$(usex system-mitkrb5 '--with-system-mitkrb5' '')
|
||||
--without-winbind
|
||||
--disable-python
|
||||
)
|
||||
fi
|
||||
|
||||
CPPFLAGS="-I${SYSROOT}/usr/include/et ${CPPFLAGS}" \
|
||||
waf-utils_src_configure ${myconf[@]}
|
||||
}
|
||||
|
||||
multilib_src_install() {
|
||||
waf-utils_src_install
|
||||
|
||||
# Make all .so files executable
|
||||
find "${D}" -type f -name "*.so" -exec chmod +x {} +
|
||||
|
||||
if multilib_is_native_abi; then
|
||||
# install ldap schema for server (bug #491002)
|
||||
if use ldap ; then
|
||||
insinto /etc/openldap/schema
|
||||
doins examples/LDAP/samba.schema
|
||||
fi
|
||||
|
||||
# create symlink for cups (bug #552310)
|
||||
if use cups ; then
|
||||
dosym /usr/bin/smbspool /usr/libexec/cups/backend/smb
|
||||
fi
|
||||
|
||||
# install example config file
|
||||
insinto /etc/samba
|
||||
doins examples/smb.conf.default
|
||||
|
||||
# Install init script and conf.d file
|
||||
newinitd "${CONFDIR}/samba4.initd-r1" samba
|
||||
newconfd "${CONFDIR}/samba4.confd" samba
|
||||
|
||||
systemd_dotmpfilesd "${FILESDIR}"/samba.conf
|
||||
systemd_dounit "${FILESDIR}"/nmbd.service
|
||||
systemd_dounit "${FILESDIR}"/smbd.{service,socket}
|
||||
systemd_newunit "${FILESDIR}"/smbd_at.service 'smbd@.service'
|
||||
systemd_dounit "${FILESDIR}"/winbindd.service
|
||||
systemd_dounit "${FILESDIR}"/samba.service
|
||||
fi
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
if multilib_is_native_abi ; then
|
||||
"${WAF_BINARY}" test || die "test failed"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ewarn "Be aware the this release contains the best of all of Samba's"
|
||||
ewarn "technology parts, both a file server (that you can reasonably expect"
|
||||
ewarn "to upgrade existing Samba 3.x releases to) and the AD domain"
|
||||
ewarn "controller work previously known as 'samba4'."
|
||||
|
||||
elog "For further information and migration steps make sure to read "
|
||||
elog "http://samba.org/samba/history/${P}.html "
|
||||
elog "http://samba.org/samba/history/${PN}-4.2.0.html and"
|
||||
elog "http://wiki.samba.org/index.php/Samba4/HOWTO "
|
||||
}
|
||||
Reference in New Issue
Block a user