games-emulation/mupen64plus-ui-console: Bump to 2.5.9

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2019-09-15 11:51:16 +02:00
parent f3bbce52e0
commit ef9f3da28c
2 changed files with 91 additions and 0 deletions
@@ -1 +1,2 @@
DIST mupen64plus-ui-console-src-2.5.9.tar.gz 58934 BLAKE2B 83fb9502ba910af75eff62a45ac490a7281db27cf7df4c666382eb922249e1483cbfcc204e79e3763d047c876558531021360078e81abb7995c855b274e182b9 SHA512 60be63e94c8a2e44a8f4f215f667bc980f62bee3ba629af53d281328f45e016dbadfc6b7596ac657fd434b9df283d43b54a058cba2cdce3fef4b865adbedd8ca
DIST mupen64plus-ui-console-src-2.5.tar.gz 47852 BLAKE2B 060d93c82b63c5870feffd665513d3a9046c3583103ccd16014865b621f33e2eafc93af5813332ab9416c4b01b6f767ed8b4ff4d08939abee60193638ce9cdb5 SHA512 70293a768c2bc5f80a2f71db229021d497d675536f5dc5eb098f91b62081f993f308d410adebce208a89880f57b037d5b42fa2f95c42ce94ffe2fca326a53046
@@ -0,0 +1,90 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
MY_P=${PN}-src-${PV}
inherit toolchain-funcs xdg-utils
DESCRIPTION="A fork of Mupen64 Nintendo 64 emulator, console UI"
HOMEPAGE="https://www.mupen64plus.org/"
SRC_URI="https://github.com/mupen64plus/${PN}/releases/download/${PV}/${MY_P}.tar.gz"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
RDEPEND=">=games-emulation/mupen64plus-core-${PV}:0=
media-libs/libsdl2:0=
!<games-emulation/mupen64plus-2.0"
DEPEND="${RDEPEND}
virtual/pkgconfig"
S=${WORKDIR}/${MY_P}
src_prepare() {
default
# avoid implicitly appending CPU flags
sed -i -e 's:-mmmx::g' -e 's:-msse::g' projects/unix/Makefile || die
# avoid appending -fPIE/-fno-PIE
sed -i -e '/^if.*PIE/,/endif/d' projects/unix/Makefile || die
}
src_compile() {
MAKEARGS=(
# Note: please keep this in sync in all of mupen64plus-* packages
-C projects/unix
# this basically means: GNU userspace
UNAME=Linux
# verbose output
V=1
CROSS_COMPILE="${CHOST}-"
CC="$(tc-getCC)"
CXX="$(tc-getCXX)"
PKG_CONFIG="$(tc-getPKG_CONFIG)"
# usual CFLAGS, CXXFLAGS and LDFLAGS are respected
# so we can leave OPTFLAGS empty
OPTFLAGS=
# paths, some of them are used at compile time
PREFIX=/usr
LIBDIR=/usr/$(get_libdir)
# disable unwanted magic
LDCONFIG=:
INSTALL_STRIP_FLAG=
# Package-specific stuff
# CROSS_COMPILE causes it to look for ${CHOST}-sdl2-config...
SDL_CFLAGS="$($(tc-getPKG_CONFIG) --cflags sdl2)"
SDL_LDLIBS="$($(tc-getPKG_CONFIG) --libs sdl2)"
)
use amd64 && MAKEARGS+=( HOST_CPU=x86_64 )
use x86 && MAKEARGS+=( HOST_CPU=i386 )
emake "${MAKEARGS[@]}" all
}
src_install() {
emake "${MAKEARGS[@]}" DESTDIR="${D}" install
dodoc README RELEASE
}
pkg_postinst() {
xdg_desktop_database_update
xdg_icon_cache_update
}
pkg_postrm() {
xdg_desktop_database_update
xdg_icon_cache_update
}