app-text/asciidoc-8.6.10_p20181016: new snapshot

Add a new snapshot ebuild based on the latest commit of Asciidoc-Py3.
Also add dev-libs/libxml2 to $RDEPEND because a2x uses xmllint directly,
as recommended by Mart Raudsepp in Gentoo bug #671668.

Closes: https://bugs.gentoo.org/661662
Package-Manager: Portage-2.3.62, Repoman-2.3.11
Signed-off-by: Marc Joliet <marcec@gmx.de>
Closes: https://github.com/gentoo/gentoo/pull/11602
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Marc Joliet
2019-04-20 08:46:08 +02:00
committed by Michał Górny
parent 1882a75aaa
commit eeef837c0a
2 changed files with 93 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST asciidoc-8.6.10.tar.gz 577208 BLAKE2B 320724c3e2306e14212a4e32f09fb735861f9b0126ce86695c6b5840b69f94d0e5befbbfc355006a10d13d34e8ed3582f0bfb678744654a7d2040555016b1681 SHA512 6ecc86977baaf1c756691e3f661e43ef2bb24e606898f6075bfa6f174d1fdc5e77d00853ffe014847e295364349d6ad34f3b8209cb97870e0233012fc38a281a
DIST asciidoc-8.6.10_p20181016.tar.gz 576694 BLAKE2B 4d255606675346d00ab03398bf48cb30d357f9f9366944e4faf66ae4c96dafce49acdd930fc848f3dbb2d704a004bb5815d17b53416a76c8368a92e4716328b2 SHA512 801f360b0c444e932f1c50897d446de0ec3f0fb2206080b5aa6dda396fede96065f7bb629a84c8a8e40c5d8897f305fdb1877512f04ae757f3b142fd3a7305d0
DIST asciidoc-8.6.9.tar.gz 907253 BLAKE2B 45db42abd9ec73f6d3b20fc755bdd501eab1503bd8d5d6bb6b7d66c442cf8bcd47ee4325dbb572bdcfd01168ef1bccc3430ee7c545e7b3a6715b8ebf09516ad9 SHA512 1984482010dbd35c3a1def67f4915ce83ecfc29a7463f84aa312107d7a9ff647978f57615462c65e885bea424eed89a212df728cc3acd3c63df1c763dfa5e955
@@ -0,0 +1,92 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{4,5,6,7} pypy3 )
inherit autotools python-single-r1 readme.gentoo-r1
DESCRIPTION="A plain text human readable/writable document format"
HOMEPAGE="http://asciidoc.org/ https://github.com/asciidoc/asciidoc-py3/"
MY_COMMIT="618f6e6f6b558ed1e5f2588cd60a5a6b4f881ca0"
SRC_URI="https://github.com/${PN}/${PN}-py3/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
LICENSE="GPL-2"
SLOT="0"
IUSE="examples graphviz highlight test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
app-text/docbook-xml-dtd:4.5
>=app-text/docbook-xsl-stylesheets-1.75
dev-libs/libxslt
dev-libs/libxml2
${PYTHON_DEPS}
graphviz? ( media-gfx/graphviz )
highlight? (
|| (
dev-util/source-highlight
dev-python/pygments[${PYTHON_USEDEP}]
app-text/highlight
)
)"
DEPEND="
test? (
app-text/dvipng
dev-texlive/texlive-latex
dev-util/source-highlight
media-gfx/graphviz
media-gfx/imagemagick
media-sound/lilypond
${PYTHON_DEPS}
)"
DOC_CONTENTS="
If you are going to use a2x, please also look at a2x(1) under
REQUISITES for a list of runtime dependencies.
"
S="${WORKDIR}/${PN}-py3-${MY_COMMIT}"
src_prepare() {
default
# Only needed for prefix - harmless (does nothing) otherwise
sed -i -e "s:^CONF_DIR=.*:CONF_DIR='${EPREFIX}/etc/asciidoc':" \
"${S}/asciidoc.py" || die
eautoreconf
}
src_configure() {
econf --sysconfdir="${EPREFIX}"/usr/share
}
src_test() {
local -x ASCIIDOC_PY=asciidoc.py
"${EPYTHON}" tests/test${PN}.py update || die
"${EPYTHON}" tests/test${PN}.py run || die
}
src_install() {
default
python_fix_shebang "${ED}"/usr/bin/*.py
readme.gentoo_create_doc
dodoc BUGS.txt CHANGELOG.txt README.asciidoc docbook-xsl/asciidoc-docbook-xsl.txt \
dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt
# Below results in some files being installed twice in different locations, but they are
# in the right place, uncompressed, and there won't be any broken links. See bug #483336
if use examples; then
# examples/website is full of relative symlinks,
# deref them for copying, which dodoc doesn't do
cp -rL examples/website "${ED%/}"/usr/share/doc/${PF}/examples || die
docompress -x /usr/share/doc/${PF}/examples
fi
}
pkg_postinst() {
readme.gentoo_print_elog
}