gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-16 14:29:05 -07:00
Code Issues Projects Releases Wiki Activity

gui-libs/xdg-desktop-portal-wlr: add 0.8.1

Browse Source 
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
2026-02-06 20:00:17 +02:00
parent d6d8e3e2c7
commit eeed5240be
2 changed files with 76 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
gui-libs/xdg-desktop-portal-wlr/Manifest
View File

@@ -1,2 +1,4 @@
DIST xdg-desktop-portal-wlr-0.7.1.gh.tar.gz 38849 BLAKE2B 41bbb177dc4df65f9ca5bc8a6c18775357e71948026864b3ca157d3d0834b41cfd4188bd1d4d2417973cac434b1b7f2a2e6b4a2fec45cd2d8b36b8a8f55a498a SHA512 87aa5255d3de3203c2bfa6986c2acbffbfd414d12fb72aeca25249d3b528ffb948858a787c9c4206b18faaddd6ce09c95c257e969cc3cfeee8e376c3846f2b9d
DIST xdg-desktop-portal-wlr-0.7.1.gh.tar.gz.sig 566 BLAKE2B 719ac0f700baf5bc337daf6b15a2cf03ec3f1dd3658af939682c55b704667007bd63bc81644bfa9f4e2f62d0c7725e59620cc9691fb0d2675e7f380cd9a203dc SHA512 bae40903a23c514f7b310f7a26c2dd878e8b12a0375d7f29e5d261b995f653cfc54522bde01b0a94aa327260b009cc951db992e59837a3099dbf5158088bdd56
DIST xdg-desktop-portal-wlr-0.8.1.tar.gz 44318 BLAKE2B e57f58718325049e9c16de3a00f43776d00027a50706df4c42b64d6030d1811d4c7c7a2972c7d995a47ee6362a0b635122feb68b54ad678789957079cc156dc4 SHA512 bbe6b007a1cb0f1d34346548c5b3e4ebefa4b07d5254389b548d62561c0e9843e9e252e0e6b18ab39ab40b8f126cf5d7b2d84d187bf3ce0b61bcbb49d41d06d1
DIST xdg-desktop-portal-wlr-0.8.1.tar.gz.sig 566 BLAKE2B aa23f1ad67f6ae3b17b7242a05a908ae42fe66f4271cf2479c3c872f8885028a6c7340178a465d0f5a7e320b27d1a1868567ef2780951d88c99ff527157d00ab SHA512 7f8af199e97074c59b88103e6c385eedced081b5473dcf77c60bcb8d4bfd1ca848beb0628a494a249189f00ec882cf45ad3d67aead53fb35ff38531bdc5ba55c

74
gui-libs/xdg-desktop-portal-wlr/xdg-desktop-portal-wlr-0.8.1.ebuild Normal file
View File

@@ -0,0 +1,74 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="xdg-desktop-portal backend for wlroots"
HOMEPAGE="https://github.com/emersion/xdg-desktop-portal-wlr"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://github.com/emersion/${PN}.git"
inherit git-r3
else
inherit verify-sig
SRC_URI="https://github.com/emersion/${PN}/releases/download/v${PV}/${P}.tar.gz
https://github.com/emersion/${PN}/releases/download/v${PV}/${P}.tar.gz.sig"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
fi
LICENSE="MIT"
SLOT="0"
IUSE="elogind systemd"
REQUIRED_USE="?? ( elogind systemd )"
DEPEND="
>=media-video/pipewire-0.3.62:=
dev-libs/inih
dev-libs/wayland
media-libs/mesa
x11-libs/libdrm
|| (
systemd? ( >=sys-apps/systemd-237 )
elogind? ( >=sys-auth/elogind-237 )
sys-libs/basu
)
"
# mesa is needed for gbm dep (which it hards sets to 'on')
RDEPEND="
${DEPEND}
sys-apps/xdg-desktop-portal
"
BDEPEND="
>=dev-libs/wayland-protocols-1.24
virtual/pkgconfig
"
if [[ ${PV} != 9999 ]]; then
BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-emersion )"
VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/emersion.asc"
fi
src_configure() {
local emesonargs=()
if use systemd; then
emesonargs+=(-Dsd-bus-provider=libsystemd)
elif use elogind; then
emesonargs+=(-Dsd-bus-provider=libelogind)
else
emesonargs+=(-Dsd-bus-provider=basu)
fi
meson_src_configure
}
src_install() {
meson_src_install
# bug #915702
insinto /usr/share/xdg-desktop-portal
doins "${WORKDIR}/${P}/contrib/wlroots-portals.conf"
exeinto /etc/user/init.d
newexe "${FILESDIR}"/xdg-desktop-portal-wlr.initd xdg-desktop-portal-wlr
}